Nix derivation for Phanpy

phanpy.nix

{
  lib,
  fetchFromGitHub,
  buildNpmPackage,
  importNpmLock,
  env ? { },
}:
buildNpmPackage (finalAttrs: rec {
  pname = "phanpy";
  version = "2026.05.21.387a188";

  src = fetchFromGitHub {
    owner = "cheeaun";
    repo = "phanpy";
    rev = finalAttrs.version;
    hash = "sha256-MahLYnIQYaiTIPaZZt6McJSQr1uPMiQ3uit6lHpTGcA=";
  };

  # Pass any environment variables through to the build.
  inherit env;

  # This makes Vite behave in a sealed environment.
  CI = true;

  npmDeps = importNpmLock { npmRoot = src; };
  npmConfigHook = importNpmLock.npmConfigHook;
  npmRebuildFlagsArray = [ "--ignore-scripts" ];

  buildPhase = ''
    runHook preBuild

    # Run the post-install scripts, which generate icons.
    npm run postinstall

    # Build with Vite.
    NODE_ENV=production npm run build

    runHook postBuild
  '';

  installPhase = ''
    runHook preInstall

    mv ./dist $out

    runHook postInstall
  '';

  meta = {
    description = "A minimalistic opinionated Mastodon web client";
    homepage = "https://phanpy.social";
    license = lib.licenses.mit;
  };
})