Insert blank rows

gistfile1.txt

// variants to https://gist.github.com/havishmad/0f8e5f785146633f0f8533b5820dd0fe

insertBlankRows=
LAMBDA( data,
    LET(
        columnsInRange, COLUMNS(data),
        emptyRow, IF( SEQUENCE(, columnsInRange ), ""),
        rowsInRange, ROWS( data ),
        addEmptyRow, VSTACK( TAKE( data, 1), emptyRow),
        IF( rowsInRange = 1,
            data,
            VSTACK( addEmptyRow,
                insertBlankRows( DROP( data, 1) ) )
        )
    ) );

////
insertBlankRowsShortened=
LAMBDA( data,
    LET(
        emptyRow, IF( SEQUENCE(, COLUMNS(data) ), ""),
        addEmptyRow, VSTACK( TAKE( data, 1), emptyRow),
        IF( ROWS( data ) = 1,
            data,
            VSTACK( addEmptyRow,
                insertBlankRows( DROP( data, 1) ) )
        )
    ) );

/// one more variant
emptyRow=
LAMBDA( numberOfColumns,
    IF( SEQUENCE(, numberOfColumns ), "")
);

groupIndex=
LAMBDA( number, groupSize,
    INT( (number-1)/groupSize) + 1 );

insertBlankRowsReduce=
LAMBDA( data,
    REDUCE(
        "",
        SEQUENCE( 2 * ROWS(data) ),
        LAMBDA( a, v,
            IF( v = SEQUENCE(v),
                IF( ISODD(v),
                    CHOOSEROWS( data, groupIndex(v, 2) ),
                    emptyRow( COLUMNS(data)) ),
                a
            ))
    ));