Pretty-print methods of a Java class in Clojure. Useful inside the REPL.

README.md

The function print-methods is intended to be used inside a REPL. Just copy and paste it to your REPL and enjoy:

main=> ; paste print-methods
main=> (print-methods 1)
class java.lang.Long
-----------
bitCount(long) -> int
byteValue() -> byte
compare(long, long) -> int
;...

print_methods.clj

(defn print-methods
  "For a class 'x', print the methods (ordered by their name) in
   the following fashion:
   
   <methodName>(<parameters if any>) -> <return value>"
  [x]
  (let [meth-seq    (-> x class .getMethods seq)
        ordered-seq (sort-by #(.getName %) meth-seq)
        params      (fn [m] 
                      (let [ptypes (.getParameterTypes m)]
                        (if (= 0 (count ptypes))
                          ""
                          (clojure.string/join ", "
                            (for [x ptypes]
                              (.getName x))))))]
    (printf "class %s\n-----------\n" (-> x class .getName))
    (doseq [m ordered-seq]
      (printf "%s(%s) -> %s\n" (.getName m) (params m) (.getReturnType m)))))

Nice! The built-in clojure.reflect does all the Java reflection to Clojure data conversion by for you by the way, so you could just rewrite this in terms of Clojure data processing too (see clojure.reflect/type-reflect for details on the format):

(use 'clojure.reflect)
(defn print-methods [c]
  (->> (reflect c) 
       :members 
       (filter :return-type)
       (sort-by :name)
       (map (fn [{:keys [name parameter-types return-type]}]
              (format "%s(%s) -> %s" name (clojure.string/join ", " parameter-types) return-type)))
       (run! println)))
(print-methods Long)

bitCount(long) -> int
byteValue() -> byte
compare(long, long) -> int
...

@puredanger Any reason for making :return-type a keyword instead of a symbol in the :keys clause?

nope, typo :) (but either works)

Thank you for your hints, gentlemen! :)

clojure.print/print-table works too.

(use 'clojure.pprint)
(defn print-methods-2 [c]
  (->> (reflect c) 
       :members 
       (filter :return-type)
       (sort-by :name)
       (map #(select-keys % [:name :parameter-types :return-type])) 
       (print-table)))

|                 :name |                  :parameter-types |         :return-type |
|-----------------------+-----------------------------------+----------------------|
|              bitCount |                            [long] |                  int |
|             byteValue |                                [] |                 byte |
|               compare |                       [long long] |                  int |
|             compareTo |                [java.lang.Object] |                  int |
|             compareTo |                  [java.lang.Long] |                  int |
|       compareUnsigned |                       [long long] |                  int |
|                decode |                [java.lang.String] |       java.lang.Long |