Advent of Code 2022

day1.fs

CREATE top3  3 CELLS ALLOT  top3 3 CELLS 0 FILL
0 VALUE file
12 CONSTANT max-line
CREATE line-buffer  max-line ALLOT

: init-file ( -- ) S" day1.txt" R/O OPEN-FILE THROW TO file ;

: free-file ( -- ) file CLOSE-FILE THROW  0 TO file ;

: step ( -- u f ) line-buffer max-line 2 - file READ-LINE THROW ;

: update-leaderboard ( u -- )
    DUP top3 @ > IF
        top3 top3 CELL+ 2 CELLS MOVE
        top3 !
    ELSE
        DUP top3 CELL+ @ > IF
            top3 CELL+ @ top3 2 CELLS + !
            top3 CELL+ !
        ELSE
            DUP top3 2 CELLS + @ > IF
                top3 2 CELLS + !
            ELSE
                DROP
            THEN
        THEN
    THEN ;

: process ( -- )
    0 BEGIN
        step
    WHILE
        ?DUP IF
            line-buffer SWAP 0. 2SWAP >NUMBER 2DROP D>S +
        ELSE
            update-leaderboard  0
        THEN
    REPEAT 2DROP ;

init-file
process
." Max: " top3 @ . CR
." Sum: " top3 @ top3 CELL+ @ + top3 2 CELLS + @ + . CR
free-file