[Gradle Tips] #Android #Gradle

app-build-google-services.gradle

    // buildTypesに応じたgoogle-services.jsonをapp/.へコピー
    gradle.taskGraph.beforeTask { Task task ->
        if (task.name ==~ /process.*GoogleServices/) {
            applicationVariants.all { variant ->
                if (task.name ==~ /(?i)process${variant.name}GoogleServices/) {
                    copy {
                        from "src/${variant.name}"
                        into "."
                        include "google-services.json"
                    }
                }
            }
        }
    }

app-build-hyperion.gradle

dependencies {
    // Debug
    [
            "hyperion-core",
            "hyperion-attr",
            "hyperion-measurement",
            "hyperion-disk",
            "hyperion-crash",
            "hyperion-shared-preferences"
    ].forEach {
        debugImplementation("com.willowtreeapps.hyperion:$it:0.9.27") {
            exclude group: 'com.android.support'
        }
    }
}

app-build-ktlint.gradle

configurations {
    ktlint
}

dependencies {
    ktlint "com.github.shyiko:ktlint:0.29.0"
}

task ktlint(type: JavaExec, group: "verification") {
    description = "Check Kotlin code style."
    classpath = configurations.ktlint
    main = "com.github.shyiko.ktlint.Main"
    args "--android", "--color", "--reporter=plain", "--reporter=checkstyle,output=${buildDir}/reports/ktlint-results.xml", "src/**/*.kt"
    ignoreExitValue true
}
check.dependsOn ktlint