Proposed new PKGBUILD for https://aur.archlinux.org/packages/drumlabooh

.gitignore

pkg/
src/
drumlabooh-*.pkg.tar.*
drumlabooh-drumkits-*.pkg.tar.*
drumlabooh-lv2-*.pkg.tar.*
drumlabooh-vst3-*.pkg.tar.*
drumlabooh-*.tar.gz
drum_sklad-*.tar.gz
juce-*.tar.gz

PKGBUILD.sh

# Maintainer: Peter Semiletov peter.semiletov at gmail dot com
# Contributor: Chris Arndt <aur -at- chrisarndt -dot- de>

_juce_version=8.0.1
_drum_sklad_version=1.0.0
pkgbase=drumlabooh
pkgname=(
  drumlabooh
  drumlabooh-drumkits
  drumlabooh-lv2
  drumlabooh-vst3
)
pkgver=6.0.0
pkgrel=2
pkgdesc='Drum machine which supports Hydrogen, Drumlabooh and SFZ drumkits'
arch=(x86_64)
license=(GPL-3.0-only)
url='https://github.com/psemiletov/drumlabooh'
makedepends=(alsa-lib curl git cmake libglvnd webkit2gtk)

source=("$pkgname-$pkgver.tar.gz::https://github.com/psemiletov/drumlabooh/archive/$pkgver.tar.gz"
        "drum_sklad-$_drum_sklad_version.tar.gz::https://github.com/psemiletov/drum_sklad/archive/refs/tags/$_drum_sklad_version.tar.gz"
        "juce-$_juce_version.tar.gz::https://github.com/juce-framework/JUCE/archive/refs/tags/$_juce_version.tar.gz")
sha256sums=('41e93f3f81a22b81569cd50de45b16c306c052b964a32f58ae2bfe55fd0d1c1c'
            'cbb9c7f80a42b171ff5ee9e68c17606e2c9e74d265811213a6e12401b4f6d4a0'
            '1a5aae997075ae2df045793fd47a4dc16234b2a7939d445fea17075219397b05')

_pick() {
  local p="$1" f d; shift
  for f; do
    d="$srcdir/$p/${f#$pkgdir/}"
    mkdir -p "$(dirname "$d")"
    mv "$f" "$d"
    rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
  done
}


build() {
  cmake \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DFETCHCONTENT_FULLY_DISCONNECTED=ON \
    -DFETCHCONTENT_SOURCE_DIR_DRUM_SKLAD="$srcdir/drum_sklad-$_drum_sklad_version" \
    -DFETCHCONTENT_SOURCE_DIR_JUCE="$srcdir/JUCE-$_juce_version" \
    -S $pkgbase-$pkgver \
    -B $pkgbase-build \
    -W no-dev
  cmake --build $pkgbase-build
}

package_drumlabooh() {
  depends=(
    $pkgbase-{drumkits,lv2,vst3}=$pkgver
  )

  DESTDIR="$pkgdir" cmake --install $pkgbase-build

  (
    cd "$pkgdir"
    _pick $pkgbase-drumkits usr/share
    _pick $pkgbase-lv2 usr/lib/lv2
    _pick $pkgbase-vst3 usr/lib/vst3
  )
}

package_drumlabooh-drumkits() {
  pkgdesc+=" - drum kits"
  groups=(pro-audio)
  mv -v $pkgname/* "$pkgdir"
}

package_drumlabooh-lv2() {
  pkgdesc+=" - LV2 plugins"
  depends=(fontconfig freetype2 gcc-libs glibc)
  groups=(lv2-plugins pro-audio)
  optdepends=('lv2-host: for loading the LV2 plugins')
  mv -v $pkgname/* "$pkgdir"
}

package_drumlabooh-vst3() {
  pkgdesc+=" - VST3 plugins"
  depends=(fontconfig freetype2 gcc-libs glibc)
  groups=(pro-audio vst3-plugins)
  optdepends=('vst3-host: for loading the VST3 plugins')
  mv -v $pkgname/* "$pkgdir"
}