Updated PKGBUILD for kicad-packages3d-git

PKGBUILD-kicad-packages3d-git.sh

# Maintainer: Frederic Van Assche <[email protected]>
# Contributor: Christopher Arndt <aur -at- chrisarndt -dot- de>

_pkgname=kicad-packages3d
pkgname="${_pkgname}-git"
pkgver=r2020.10.06.27d653ce
pkgrel=1
pkgdesc="KiCad component 3D model libraries from the official git repo"
arch=('any')
url="https://github.com/KiCad/kicad-packages3D"
license=('GPL')
options=('!strip')
makedepends=('cmake' 'git')
conflicts=('kicad-library-bzr' 'kicad-library-git' 'kicad-library-3d' 'kicad-library' 'kicad-packages' 'kicad-packages3d')
provides=('kicad-packages3d')
source=("${_pkgname}::git+https://gitlab.com/kicad/libraries/kicad-packages3D")
md5sums=('SKIP')

pkgver() {
  cd "${srcdir}/${_pkgname}"
  _DATE=$(date -d @`git log -1 --format="%at"` --rfc-3339='date')
  printf "r%s.%s" "${_DATE//-/.}" "$(git rev-parse --short HEAD)"
}

build() {
  cd "$srcdir/${_pkgname}"
  mkdir -p build
  cd build
  cmake .. -DCMAKE_BUILD_TYPE=Release -DCMAKE_INSTALL_PREFIX=/usr
}

package() {
  cd "$srcdir/${_pkgname}/build"

  make DESTDIR="${pkgdir}/" install
}