CommandThatMakesRequest.as

public class WarnIfCurrentEditDataIsChangedCommand extends Command
{
	[Inject]
	public var getEditedVOSignalResponsePair:GetEditedVOSignalResponsePair;

	[Inject]
	public var editingModel:IEditingModel;
	
	[Inject]
	public var dataChangeEvent:AdminDataEvent;
				
	override public function execute():void 
	{
		getEditedVOSignalResponsePair.addToResponse(compareData);
		getEditedVOSignalResponsePair.dispatchRequest();
	}
		
	private function compareData(editedVO:AdminDataVO):void
	{
		var currentStoredVO:AdminDataVO = editingModel.itemBeingEdited;
		
		if(ObjectUtil.compare(currentStoredVO, editedVO) == 0)
		{
			editingModel.itemBeingEdited = dataChangeEvent.adminDataVO;
			return;
		}
		else
		{
			// create the warning dialog with handlers
		}
	} 
}

GetEditedVOSignalResponsePair.as

public class  GetEditedVOSignalResponsePair extends SyncSignalResponsePair {
		
	public function  GetEditedVOSignalResponsePair() {
		super([], [AdminDataVO]);
	} 
}

MappingInContextOrCommand.as

	// we have to create the Signal so that the mediator can register the handler even before it is injected
	// this is for RL 1.0 - might not be required in later versions

	var getEditedVOSignalResponsePair:GetEditedVOSignalResponsePair = new GetEditedVOSignalResponsePair();
	injector.mapValue(GetEditedVOSignalResponsePair, getEditedVOSignalResponsePair); 

MediatorThatResponds.as

	[Inject]
	public var getEditedVOSignalResponsePair:GetEditedVOSignalResponsePair;
		
	override public function onRegister():void
	{			
		getEditedVOSignalResponsePair.addToRequest(respondWithVO);
	}

	private function respondWithVO(responseSignal:Signal):void
	{
		var accountVO:AccountDataVO = view.populateVO();
		responseSignal.dispatch(accountVO);
	}