How to get latest git tag or commit ID (gradle)

git_tag_or_version_gradle.md

How to get latest git tag or commit ID (gradle)

The following will give you the latest git tag name (if the HEAD is tagged) or latest commit ID otherwise. The getAppVersion function returns the end value.

Why is this useful?

I use it to name packages of my builds and other versioning purposes in my Android projects.

The code:

def getAppVersion = { ->
    def stdout = new ByteArrayOutputStream()
    exec {
        commandLine 'git', 'rev-parse', '--short', 'HEAD'
        standardOutput = stdout
    }
    def commitId = stdout.toString().replace("\n", "").replace("\r", "").trim()
    stdout = new ByteArrayOutputStream()
    exec {
        commandLine 'git', 'tag', '--points-at', commitId
        standardOutput = stdout
    }
    def tagName = stdout.toString().replace("\n", "").replace("\r", "").trim()
    def versionName = 'git-' + commitId
    if (tagName != null && "" != tagName) {
        versionName = tagName
    }
    return versionName
}

A KTS version

fun getGitTag(): String {
  val stdout = ByteArrayOutputStream()
  val stdout2 = ByteArrayOutputStream()
  exec {
    workingDir("change directory to root")
    commandLine("git", "rev-parse", "--short", "HEAD")
    standardOutput = stdout
  }
  val commitId = stdout.toString().replace("\n", "").replace("\r", "").trim()
  exec {
    workingDir("change directory to root")
    commandLine("git", "tag", "--points-at", commitId)
    standardOutput = stdout2
  }
  val tagName = stdout2.toString().replace("\n", "").replace("\r", "").trim()
  var versionName = commitId
  if (tagName.isNotEmpty()) {
    versionName = tagName
  }
  return versionName
}