Anet A8 Y axis belt tensioner

belt tensioner back

$fn=20;

module holder () {
    difference() {
        // create rounded corners cube
        rcube([20, 30, 20]);
 
        // make a hole for the screw
        translate([10, 10, 0])
            screwHole();
        
        // make back side flat
        translate([-1, 17, -1])
            cube(50);
    }
}

module rcube (vector, radius = 5) {
    x = vector[0];
    y = vector[1];
    z = vector[2];
    hull() {
        rcube4([x, y, z-radius], radius);
        translate([radius, radius, z-radius])
            sphere(radius);
        translate([x-radius, radius, z-radius])
            sphere(radius);
        translate([x-radius, y-radius, z-radius])
            sphere(radius);
        translate([radius, y-radius, z-radius])
            sphere(radius);
    }
}

module rcube4(vector, radius) {
    x = vector[0];
    y = vector[1];
    z = vector[2];
    hull() {
        translate([radius, radius, 0])
            cylinder(r=radius, h=z);
        translate([x-radius, radius, 0])
            cylinder(r=radius, h=z);
        translate([x-radius, y-radius, 0])
            cylinder(r=radius, h=z);
        translate([radius, y-radius, 0])
            cylinder(r=radius, h=z);
    }
}


module screwHole () {
    translate([0, 0, -1])
        cylinder(d=4, h=22);
    translate([0, 0, 17]) 
        cylinder(d=10, h=4);
}


holder();