esp8266-mqtt-get-deepsleep

esp8266-Adafruit_MQTT-get-deepsleep.ino

/***************************************************
  Adafruit MQTT Library ESP8266 Example

  Must use ESP8266 Arduino from:
    https://github.com/esp8266/Arduino

  Works great with Adafruit's Huzzah ESP board & Feather
  ----> https://www.adafruit.com/product/2471
  ----> https://www.adafruit.com/products/2821

  Adafruit invests time and resources providing this open source code,
  please support Adafruit and open-source hardware by purchasing
  products from Adafruit!

  Written by Tony DiCola for Adafruit Industries.
  MIT license, all text above must be included in any redistribution
 ****************************************************/
#include <ESP8266WiFi.h>
#include "Adafruit_MQTT.h"
#include "Adafruit_MQTT_Client.h"

/************************* WiFi Access Point *********************************/

#define WLAN_SSID    "normalnet"
#define WLAN_PASS    "the bachman family"

/************************* Adafruit.io Setup *********************************/

#define AIO_SERVER      "io.adafruit.com"
#define AIO_SERVERPORT  8883                   // use 8883 for SSL
#define AIO_USERNAME    "abachman"
#define AIO_KEY         "68cc3647cd5d446f827dd1609364cd2f"

/************ Gl/obal State (you don't need to change this!) ******************/

WiFiClientSecure client;

// Setup the MQTT client class by passing in the WiFi client and MQTT server and login details.
Adafruit_MQTT_Client mqtt(&client, AIO_SERVER, AIO_SERVERPORT, AIO_USERNAME, AIO_USERNAME, AIO_KEY);

/****************************** Feeds ***************************************/

// Notice MQTT paths for AIO follow the form: <username>/feeds/<feedname>
Adafruit_MQTT_Subscribe onoffbutton = Adafruit_MQTT_Subscribe(&mqtt, AIO_USERNAME "/feeds/onoff");
Adafruit_MQTT_Publish onoff_get = Adafruit_MQTT_Publish(&mqtt, AIO_USERNAME "/feeds/onoff/get");


/**************************** NeoPixels *************************************/

#include <Adafruit_NeoPixel.h>
#define PIN       4
#define NUMPIXELS 7
Adafruit_NeoPixel pixels = Adafruit_NeoPixel(NUMPIXELS, PIN, NEO_GRB + NEO_KHZ800);

void lightOn() {
  for(int i=0; i<pixels.numPixels(); i++){
    pixels.setPixelColor(i, pixels.Color(0,150,0));
  }
  pixels.show();
}

void lightOff() {
  pixels.clear();
  pixels.show();
}

/*************************** Sketch Code ************************************/

// Bug workaround for Arduino 1.6.6, it seems to need a function declaration
// for some reason (only affects ESP8266, likely an arduino-builder bug).
void MQTT_connect();

void setup() {
  Serial.begin(115200);
  Serial.setTimeout(2000);

  // Wait for serial to initialize. Comment out if device isn't connected to
  // Serial port during use. 
  // while(!Serial) { }
  
  pixels.begin();
  pixels.setPixelColor(0, pixels.Color(150, 0, 0));
  pixels.show();

  Serial.println(F("Adafruit MQTT demo"));

  // Connect to WiFi access point.
  Serial.println(); Serial.println();
  Serial.print("Connecting to ");
  Serial.println(WLAN_SSID);

  WiFi.begin(WLAN_SSID, WLAN_PASS);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println();
  Serial.println("WiFi connected");
  Serial.println("IP address: "); Serial.println(WiFi.localIP());
  lightOff();
  
  // Setup MQTT subscription for onoff & slider feed.
  mqtt.subscribe(&onoffbutton);
}

uint32_t x=0;
uint32_t counter=0;


void loop() {

  Serial.println("loop start");
  
  // Ensure the connection to the MQTT server is alive (this will make the
  // first connection and automatically reconnect when disconnected).  See the
  // MQTT_connect function definition further below.
  MQTT_connect();

  // This is our 'wait for incoming subscription packets' busy subloop try to
  // spend your time here
  Adafruit_MQTT_Subscribe *subscription;
  while ((subscription = mqtt.readSubscription(5000))) {
    // Check if its the onoff button feed
    if (subscription == &onoffbutton) {
      Serial.print(F("On-Off button: "));
      Serial.println((char *)onoffbutton.lastread);
      
      if (strcmp((char *)onoffbutton.lastread, "ON") == 0) {
        lightOn();
      }
      if (strcmp((char *)onoffbutton.lastread, "OFF") == 0) {
        lightOff();
      }
    }
  }

  // Ping the server to keep the mqtt connection alive.
  if(! mqtt.ping()) {
    mqtt.disconnect();
  }

  Serial.print("sleep 30 seconds"); 
  ESP.deepSleep(30000 * 1000, WAKE_RF_DEFAULT);
}

// Function to connect and reconnect as necessary to the MQTT server.
// Should be called in the loop function and it will take care if connecting.
void MQTT_connect() {
  int8_t ret;

  // Stop if already connected.
  if (mqtt.connected()) {
    return;
  }

  Serial.print("Connecting to MQTT... ");

  uint8_t retries = 3;
  while ((ret = mqtt.connect()) != 0) { // connect will return 0 for connected
    Serial.println(mqtt.connectErrorString(ret));
    Serial.println("Retrying MQTT connection in 5 seconds...");
    mqtt.disconnect();
    delay(5000);  // wait 5 seconds
    retries--;
    if (retries == 0) {
     // basically die and wait for WDT to reset me
     while (1);
    }
  }
  Serial.println("MQTT Connected!");
  pixels.setPixelColor(0, pixels.Color(0,0,150));
  pixels.show();
  delay(100);
  lightOff();
  
  // publish to {username}/feeds/onoff/get to trigger the last value resend 
  // once the connection is established or restored
  Serial.println("publishing to /get");
  onoff_get.publish(0);
}