A Nix Flake example for an Haskell application

flake.nix

{
  description = "An Haskell application";

  inputs = {
    nixpkgs.url = github:NixOS/nixpkgs;
    flake-utils.url = github:numtide/flake-utils;
    easy-hls-src.url = github:jkachmar/easy-hls-nix;
  };

  outputs = { self, nixpkgs, flake-utils, easy-hls-src }:
    flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = import nixpkgs { inherit system; };
        easy-hls = pkgs.callPackage easy-hls-src {};
        app = pkgs.haskellPackages.callCabal2nix "Application" (./src) {};
        shell = pkgs.mkShell {
          buildInputs = [
            pkgs.ghc
            pkgs.cabal-install
            pkgs.hlint
            easy-hls
          ];
          shellHook = ''
            emacsclient --suppress-output --eval "(progn
              (setenv \"PATH\" (concat (getenv \"PATH\") \":$PATH\"))
              (setq exec-path (append exec-path (split-string \"$PATH\" \":\")))
            )"
          '';
        };
      in
        rec {
          defaultPackage = app;
          defaultApp = flake-utils.lib.mkApp { drv = app; };
          devShell = shell;
        }
    );
}