Some default `just` commands for Django projects

justfile.md

just manage

# Manage
manage *ARGS='':
  uv run --all-extras python3 manage.py {{ ARGS }}

just run

# Run the development server
run port='8000':
  just manage runserver 0:{{ port }}

just bake

# Make database migrations
bake:
  just manage makemigrations

just migrate

# Run database migrations
migrate *ARGS='':
  just manage migrate {{ ARGS }}

just dance

# Do the migration dance (make migrations and migrate them)
dance:
  just bake
  just migrate

just test

# Run the tests
test *ARGS='':
  -uv run --all-extras pytest {{ ARGS }}

just lint

# Lint the project
lint *ARGS='.':
  -uvx ruff check {{ ARGS }}

just type

# Check the types in the project
type *ARGS='.':
  -uv run --all-extras mypy {{ ARGS }}  # need to run through uv to see installed dependencies

just coverage

# Run coverage on the code
coverage:
  -uv run --all-extras pytest --cov={{ src }}

just develop

# Run all the dev things
develop:
  just lint
  just type
  just coverage

My actual justfile is in https://github.com/adamghill/dotfiles/.