Auto-reconnecting websockets without changing any code

websocket-reconnect.coffee

{EventEmitter} = require "events"
backoff = require "backoff"
WebSocket = require "ws"

class EverSocket extends EventEmitter
  constructor: (url, options) ->
    @connected = false
    @reconnect = true
    
    @backoff = backoff.fibonacci()
    
    connect = =>      
      return if @connected
      return unless @reconnect
      
      @emit "reconnect"
      @socket = new WebSocket(url, options)
      
      onError = (err) =>
        @socket.removeListener "error", onError
        @emit "error", err
        unless @connected
          onClose err
      
      onClose = (err) =>
        connected = @connected
        
        @connected = false
        @socket.removeListener "close", onClose
        if connected
          @emit "close"
        if @reconnect
          try
            @backoff.backoff()
          catch err
            # ignore error
      
      @socket.on "message", (message) =>
        @emit "message", message
      @socket.on "error", onError
      @socket.on "close", onClose
      
      @socket.once "open", =>
        @backoff.reset()
        @connected = true
        @emit "open"
    
    @backoff.on "fail", (err) =>
      @reconnect = false
      @emit "error", err
    
    @backoff.on "ready", connect
    connect()
  
  send: ->
    @socket.send.apply(@socket, arguments)
  
  close: ->
    @reconnect = false
    
    if @socket
      @socket.close()

module.exports = EverSocket