Robotlegs & Flex: automediate popups

MyDirtyConfig.as

package
{
	import flash.display.DisplayObject;
	import flash.display.DisplayObjectContainer;
	
	import mx.core.IUIComponent;
	import mx.managers.ISystemManager;
	
	import robotlegs.bender.extensions.mediatorMap.api.IMediatorMap;
	import robotlegs.bender.extensions.viewManager.api.IViewManager;

	public class MyDirtyConfig
	{
		[Inject]
		public var contextView:DisplayObjectContainer;
		
		[Inject]
		public var mediatorMap:IMediatorMap;

		[Inject]
		public var viewManager:IViewManager;
		
		private function getTopLevelSystemManager(parent:DisplayObject):ISystemManager
		{
			var sm:ISystemManager;
			
			var localRoot:DisplayObjectContainer = DisplayObjectContainer(IUIComponent(parent).systemManager);
			if (localRoot is ISystemManager)
			{
				sm = ISystemManager(localRoot);
				if (!sm.isTopLevel())
					sm = sm.topLevelSystemManager;
			}
			
			return sm;
		}
		
		[PostConstruct]
		public function setup():void
		{
			var sm:ISystemManager = getTopLevelSystemManager(contextView);
			
			viewManager.removeContainer(contextView);
			viewManager.addContainer(sm as DisplayObjectContainer);
			
			// Now callouts and all kind of popups in general will be auto-mediated
			
			mediatorMap.map(CustomCallout).toMediator(CalloutMediator);
		}
		
	}
}