Cookie.re

module Lifetime = {
  type t =
    | Months(int)
    | Days(int)
    | Hours(int)
    | Minutes(int)
    | Seconds(int)
    | Session
    | Short;

  let monthsToDays = months => (months * 30)->Float.fromInt;
  let hoursToDays = hours => hours->Float.fromInt /. 24.0;
  let minutesToDays = minutes => minutes->Float.fromInt /. (60.0 *. 24.0);
  let secondsToDays = seconds =>
    seconds->Float.fromInt /. (60.0 *. 60.0 *. 24.0);

  let expires =
    fun
    | Months(x) => Some(x->monthsToDays)
    | Days(x) => Some(x->Float.fromInt)
    | Hours(x) => Some(x->hoursToDays)
    | Minutes(x) => Some(x->minutesToDays)
    | Seconds(x) => Some(x->secondsToDays)
    | Short => Some(10->minutesToDays)
    | Session => None;
};

let options = (~lifetime) => {
  "domain": Env.webHostname,
  "path": "/",
  "secure": true,
  "expires": lifetime->Lifetime.expires->Js.Nullable.fromOption,
};

let get = name => name->JsCookie.get->Js.Nullable.toOption;

let set = (~name: string, ~value: string, ~lifetime: Lifetime.t) =>
  name->JsCookie.set(value, options(~lifetime));

let remove = (~name: string, ~lifetime: Lifetime.t) =>
  name->JsCookie.remove(options(~lifetime));

JsCookie.re

type name = string;
type value = string;
type options = {
  .
  "domain": string,
  "path": string,
  "expires": Js.nullable(float),
  "secure": bool,
};

[@bs.module "js-cookie"] external get: name => Js.nullable(value) = "get";
[@bs.module "js-cookie"] external set: (name, value, options) => unit = "set";
[@bs.module "js-cookie"] external remove: (name, options) => unit = "remove";