Quick and Dirty Game of Life in CoffeeScript (30 mins in)

gol.coffee

_ = require('./underscore')

makeGrid = (height, width) =>
  _.map(_.range(height), -> _.map(_.range(width), -> undefined))


GRID_SIZE = 80

grid = makeGrid(GRID_SIZE, GRID_SIZE)

getCell = (x,y) =>
  grid[x]?[y]

getNeighbours = (x,y) =>
  neighbours = []
  for xx in _.range(x-1, x+2)
    for yy in _.range(y-1, y+2)
      continue if xx == x and yy == y
      neighbours.push(getCell(xx,yy))
  return neighbours

countAlive = (cells) =>
  _.filter(cells, (c) -> c == true).length

applyRule = (x,y) =>
  neighbours = getNeighbours(x,y)
  alive = countAlive(neighbours)
  current = getCell(x,y)
  if current
    if alive in [2,3]
      return true
    else
      return false
  else
    if alive == 3
      return true
  return current

nextGrid = =>
  for x in _.range(GRID_SIZE)
    for y in _.range(GRID_SIZE)
      applyRule(x,y)

runit = (iterations) =>
  _.times iterations, (i) =>
    console.log("\f")
    console.log("---------------------------")
    console.log("Iteration ", i)
    console.log("---------------------------")
    print()
    grid = nextGrid()

print  = =>
  printCell = (cell) =>
    if cell
     "\u2589"
    else if cell?
      "-"
    else
      " "
  console.log(_.map(grid, (line) => _.map(line, printCell).join("")).join("\n"))


addPattern = (pat, x=0, y=0) =>
  pat = pat.trim().split("\n")
  for line, xx in pat
    console.log(xx, line)
    for cell, yy in line
      console.log(yy, cell)
      grid[x+xx][y+yy] = cell == '*'

fpentomino = """
.**
**.
.*.
"""

addPattern(fpentomino, 50, 50)
addPattern(fpentomino, 20, 10)

# # Blinker
# grid[5][5] = true
# grid[5][4] = true
# grid[5][3] = true

runit(1000)