Runs a windowed Audiosurf with the proper resolution based on config.ini

audiosurf_launcher.ahk

#NoEnv
#NoTrayIcon
#SingleInstance force

SetWorkingDir, %A_ScriptDir%

If (FileExist("Audiosurf.exe") && FileExist("config.ini")) {
	ScreenWidth := 800
	ScreenHeight := 480
	
	Loop, Read, config.ini
	{
		CurrentSetting := StrSplit(A_LoopReadLine, ":")
		CurrentSettingName := Trim(CurrentSetting[1])
		CurrentSettingValue := Trim(CurrentSetting[2])
		
		If (CurrentSettingName == "resolutionwidth" && RegExMatch(CurrentSettingValue, "^\d+$")) {
			ScreenWidth := Trim(CurrentSettingValue)
		}
		Else If (CurrentSettingName == "resolutionheight" && RegExMatch(CurrentSettingValue, "^\d+$")) {
			ScreenHeight := Trim(CurrentSettingValue)
		}
	}
	
	ScreenPosX := (A_ScreenWidth / 2) - (ScreenWidth / 2)
	ScreenPosY := (A_ScreenHeight / 2) - (ScreenHeight / 2)
	
	Run, Audiosurf.exe
	ProcessIdentifier := "ahk_exe QuestViewer.exe"
	WinWaitActive, %ProcessIdentifier%
	WinMove, %ProcessIdentifier%, , %ScreenPosX%, %ScreenPosY%, %ScreenWidth%, %ScreenHeight%
}