minimal AST dumping utility for GHC 9.2

Main.hs

{-# LANGUAGE OverloadedStrings #-}

module Main where

import GHC.Data.Bag
import qualified GHC.Data.EnumSet as EnumSet
import GHC.Data.StringBuffer
import GHC.Hs.Dump
import GHC.Parser
import GHC.Parser.Errors.Ppr
import GHC.Parser.Lexer
import GHC.Types.SrcLoc
import GHC.Utils.Outputable
import GHC.Utils.Ppr
import System.IO

main :: IO ()
main = do
  src <- stringToStringBuffer <$> readFile "Test.hs"
  let enabledWarnings = EnumSet.empty
      enabledExtensions = EnumSet.empty
      safeImports = False
      haddockComments = True
      regularComments = True
      respectLineColumnPragmas = True
      parserOpts =
        mkParserOpts
          enabledWarnings
          enabledExtensions
          safeImports
          haddockComments
          regularComments
          respectLineColumnPragmas
      srcLoc = mkRealSrcLoc "<input>" 1 1
      pState = initParserState parserOpts src srcLoc
      parseResult = unP parseModule pState
  case parseResult of
    PFailed pState -> printErrorsWarnings pState
    POk pState hsMod -> do
      printErrorsWarnings pState
      printSDoc' stdout $ showAstData NoBlankSrcSpan NoBlankEpAnnotations hsMod
  where
    printSDoc' = printSDocLn defaultSDocContext (PageMode True)
    printErrorsWarnings pState = do
      let (warnings, errors) = getMessages pState
          msgBag = (pprWarning <$> warnings) `unionBags` (pprError <$> errors)
      hPutStr stderr . show . bagToList $ msgBag