Rimlight when obscured shader for Timothy

OutlineWhenObscured.shader

Shader "Custom/OutlineWhenObscured"
{
	Properties
	{
		_Color("Color", Color) = (1,1,1,1)
		_MainTex("Albedo (RGB)", 2D) = "white" {}
		_Glossiness("Smoothness", Range(0,1)) = 0.5
		_Metallic("Metallic", Range(0,1)) = 0.0

		_ObscuredColor("ObscuredColor", Color) = (1,0,0,1)

	}
		SubShader
		{
			// color when obscured
			Pass {
				Tags { "Queue" = "Transparent" "IgnoreProjector" = "True" "RenderType" = "Transparent"}
				ZWrite Off
				ZTest Always
				Blend SrcAlpha OneMinusSrcAlpha

				CGPROGRAM
					#pragma vertex vert
					#pragma fragment frag
					#include "UnityCG.cginc"

					fixed4 _ObscuredColor;

					struct appdata_t {
						float4 vertex : POSITION;
						float3 normal : NORMAL;
					};

					struct v2f {
						float4 vertex : SV_POSITION;
						float rim : TEXCOORD0;
					};

					v2f vert(appdata_t v)
					{
						v2f o;
						o.vertex = UnityObjectToClipPos(v.vertex);

						float3 viewDir = normalize(ObjSpaceViewDir(v.vertex));
						float dotProduct = 1 - dot(v.normal, viewDir);
						float rimWidth = 0.7;
						o.rim = smoothstep(1 - rimWidth, 1.0, dotProduct);
						return o;
					}

					fixed4 frag(v2f i) : SV_Target
					{
						fixed4 col = _ObscuredColor;
						col.a = i.rim;
						return col;
					}

				ENDCG

			}

			Tags { "RenderType" = "Opaque" "Queue" = "Transparent+1"}
			LOD 200

			CGPROGRAM
						// Physically based Standard lighting model, and enable shadows on all light types
						#pragma surface surf Standard fullforwardshadows

						// Use shader model 3.0 target, to get nicer looking lighting
						#pragma target 3.0

						sampler2D _MainTex;

						struct Input
						{
							float2 uv_MainTex;
						};

						half _Glossiness;
						half _Metallic;
						fixed4 _Color;

						// Add instancing support for this shader. You need to check 'Enable Instancing' on materials that use the shader.
						// See https://docs.unity3d.com/Manual/GPUInstancing.html for more information about instancing.
						// #pragma instancing_options assumeuniformscaling
						UNITY_INSTANCING_BUFFER_START(Props)
							// put more per-instance properties here
						UNITY_INSTANCING_BUFFER_END(Props)

						void surf(Input IN, inout SurfaceOutputStandard o)
						{
							// Albedo comes from a texture tinted by color
							fixed4 c = tex2D(_MainTex, IN.uv_MainTex) * _Color;
							o.Albedo = c.rgb;
							// Metallic and smoothness come from slider variables
							o.Metallic = _Metallic;
							o.Smoothness = _Glossiness;
							o.Alpha = c.a;
						}
						ENDCG
		}
			FallBack "Diffuse"
}