dots >:)

gistfile1.pde

int[][] result;
float t;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3);

void setup() {
  setup_();
  result = new int[width*height][3];
}

void draw() {

  if (!recording) {
    t = mouseX*1.0/width;
    draw_();
  } else {
    for (int i=0; i<width*height; i++)
      for (int a=0; a<3; a++)
        result[i][a] = 0;

    for (int sa=0; sa<samplesPerFrame; sa++) {
      t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
      draw_();
      loadPixels();
      for (int i=0; i<pixels.length; i++) {
        result[i][0] += pixels[i] >> 16 & 0xff;
        result[i][1] += pixels[i] >> 8 & 0xff;
        result[i][2] += pixels[i] & 0xff;
      }
    }

    loadPixels();
    for (int i=0; i<pixels.length; i++)
      pixels[i] = 0xff << 24 | 
        int(result[i][0]*1.0/samplesPerFrame) << 16 | 
        int(result[i][1]*1.0/samplesPerFrame) << 8 | 
        int(result[i][2]*1.0/samplesPerFrame);
    updatePixels();

    saveFrame("f###.gif");
    if (frameCount==numFrames)
      exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 4;
int numFrames = 240;        
float shutterAngle = .6;

boolean recording = false;

void setup_() {
  size(500, 500);
  rectMode(CENTER);
  fill(32);
  noStroke();
}

float x, y, tt;
int N = 16;
float ii;
int a, n = 13;
float d;
float r;
float ll;

void draw_() {
  background(250); 
  pushMatrix();
  translate(width/2, height/2);
  for (int i=0; i<N; i++) {
    ii = i + 4*t;
    pushMatrix();
    rotate(TWO_PI*ii/N);
    translate(100, 0);
    for (int a=0; a<n; a++) {
      if(i%2 == 0){
        r = 75;
        ll = .03;
      }
      else{
        r = 45;
        ll = .02;
      }
      pushMatrix();
      rotate((1+(i%2))*TWO_PI*(t-ll*a) + .75*PI*(i%2));
      d = 15*exp(-.115*a);
      if(i%2 != 0)
        d *= .8;
      fill(32);
      ellipse(r, 0, d, d);
      fill(250);
      if((a+i/2)%2 == 0)
      ellipse(r,0,max(0,d-3),max(0,d-3));
      popMatrix();
    }
    popMatrix();
  }
  popMatrix();
  
  copy(0,0,width/2,height,width,height,-width/2,-height);  // get overlaps right
}