cube blast

cubeBlast.pde

// blastin cubes by dave whyte

int[][] result;
float t, c;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3), ia = atan(sqrt(.5));

void push() {
  pushMatrix();
  pushStyle();
}

void pop() {
  popStyle();
  popMatrix();
}

void draw() {

  if (!recording) {
    t = mouseX*1.0/width;
    c = mouseY*1.0/height;
    if (mousePressed)
      println(c);
    draw_();
  } else {
    for (int i=0; i<width*height; i++)
      for (int a=0; a<3; a++)
        result[i][a] = 0;

    c = 0;
    for (int sa=0; sa<samplesPerFrame; sa++) {
      t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
      draw_();
      loadPixels();
      for (int i=0; i<pixels.length; i++) {
        result[i][0] += pixels[i] >> 16 & 0xff;
        result[i][1] += pixels[i] >> 8 & 0xff;
        result[i][2] += pixels[i] & 0xff;
      }
    }

    loadPixels();
    for (int i=0; i<pixels.length; i++)
      pixels[i] = 0xff << 24 | 
        int(result[i][0]*1.0/samplesPerFrame) << 16 | 
        int(result[i][1]*1.0/samplesPerFrame) << 8 | 
        int(result[i][2]*1.0/samplesPerFrame);
    updatePixels();

    saveFrame("f###.gif");
    if (frameCount==numFrames)
      exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 8;
int numFrames = 160;        
float shutterAngle = .4;

boolean recording = false;

void setup() {
  size(720, 720, P3D);
  result = new int[width*height][3];
  rectMode(CENTER);
  ortho();
  smooth(8);
}

float x, y, z, tt;
int N = 2;
float l = 36, ff = 1.5;

void cube() {
  stroke(0);
  strokeWeight(3);
  box(l);
  noFill();
  strokeWeight(2);
  box(l+1);
  strokeWeight(1);
  box(l+2);
}

float am, zz = l*2, th = PI;

void draw_() {
  am = map(cos(TWO_PI*t),1,-1,0,1);
  am = ease(am,4);
  
  background(255); 
  push();
  translate(width/2, height/2);
  rotateX(-ia);
  rotateY(QUARTER_PI-HALF_PI*t);
  for (int i=-N; i<=N; i++) {
    for (int j=-N; j<=N; j++) {
      for (int k=-N; k<=N; k++) {
        randomSeed(123*i+234*j+345*k+456);
        push();
        translate(randomGaussian()*zz*am,randomGaussian()*zz*am,randomGaussian()*zz*am);
        translate(i*l*ff,j*l*ff,k*l*ff);
        rotateZ(random(th)*am);
        rotateX(random(th)*am);
        rotateY(random(th)*am);
        rotateZ(int(random(4))*HALF_PI);
        rotateY(int(random(4))*HALF_PI);
        rotateX(int(random(4))*HALF_PI);
        fill(255);
        cube();
        pop();
      }
    }
  }
  for (int i=-N; i<N; i++) {
    for (int j=-N; j<N; j++) {
      for (int k=-N; k<N; k++) {
        randomSeed(234*i+345*j+456*k+567);
        push();
        translate(randomGaussian()*zz*am,randomGaussian()*zz*am,randomGaussian()*zz*am);
        translate((i+.5)*l*ff,(j+.5)*l*ff,(k+.5)*l*ff);
        rotateZ(random(th)*am);
        rotateX(random(th)*am);
        rotateY(random(th)*am);
        rotateZ(int(random(4))*HALF_PI);
        rotateY(int(random(4))*HALF_PI);
        rotateX(int(random(4))*HALF_PI);
        fill(0);
        cube();
        pop();
      }
    }
  }
  pop();
}