wave.pde

int[][] result;
float t, c;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3);

void setup() {
  setup_();
  result = new int[width*height][3];
}

void draw() {
  
  if(!recording){
    t = mouseX*1.0/width;
    c = mouseY*1.0/height;
    if(mousePressed)
        println(c);
    draw_();
  }
  
  else {
  for (int i=0; i<width*height; i++)
    for (int a=0; a<3; a++)
      result[i][a] = 0;

  c = 0;
  for (int sa=0; sa<samplesPerFrame; sa++) {
    t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
    draw_();
    loadPixels();
    for (int i=0; i<pixels.length; i++) {
      result[i][0] += pixels[i] >> 16 & 0xff;
      result[i][1] += pixels[i] >> 8 & 0xff;
      result[i][2] += pixels[i] & 0xff;
    }
  }

  loadPixels();
  for (int i=0; i<pixels.length; i++)
    pixels[i] = 0xff << 24 | 
      int(result[i][0]*1.0/samplesPerFrame) << 16 | 
      int(result[i][1]*1.0/samplesPerFrame) << 8 | 
      int(result[i][2]*1.0/samplesPerFrame);
  updatePixels();

  saveFrame("f###.gif");
  if (frameCount==numFrames)
    exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 8;
int numFrames = 96;        
float shutterAngle = .4;

boolean recording = false;

void setup_() {
  size(540,500,P3D);
  rectMode(CENTER);
  colorMode(HSB,1);
  smooth(4);
  stroke(1);
  strokeWeight(2);
  noStroke();
}

float x, y, z, hu, tt;
int N = 8;
float l = 17;
float dd;

void draw_() {
  background(0); 
  pushMatrix();
  translate(width/2, height/2);
  rotateX(.8);
  rotate(t*HALF_PI);
  for(int i=-N; i<=N; i++){
    for(int j=-N; j<=N; j++){
      x = i*l;
      y = j*l;
      dd = pow(dist(x,y,0,0)/l,1.5);
      tt = t - 0.03*dd;
      z = 40 + 1.5*l*cos(TWO_PI*tt);
      hu = (10 - 0.008*dist(x,y,0,0) + t) % 1;
      hu = int(hu*24)/24.0;
      fill(hu,.9,.9);
      pushMatrix();
      translate(x,y,z);
      box(l);
      popMatrix();
    }
  }
  popMatrix();
}