pizza gif processing code

pizza.pde

int[][] result;
float t, c;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3), ia = atan(sqrt(.5));

void push() {
  pushMatrix();
  pushStyle();
}

void pop() {
  popStyle();
  popMatrix();
}

void draw() {

  if (!recording) {
    t = mouseX*1.0/width;
    c = mouseY*1.0/height;
    if (mousePressed)
      println(c);
    draw_();
  } else {
    for (int i=0; i<width*height; i++)
      for (int a=0; a<3; a++)
        result[i][a] = 0;

    c = 0;
    for (int sa=0; sa<samplesPerFrame; sa++) {
      t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
      draw_();
      loadPixels();
      for (int i=0; i<pixels.length; i++) {
        result[i][0] += pixels[i] >> 16 & 0xff;
        result[i][1] += pixels[i] >> 8 & 0xff;
        result[i][2] += pixels[i] & 0xff;
      }
    }

    loadPixels();
    for (int i=0; i<pixels.length; i++)
      pixels[i] = 0xff << 24 | 
        int(result[i][0]*1.0/samplesPerFrame) << 16 | 
        int(result[i][1]*1.0/samplesPerFrame) << 8 | 
        int(result[i][2]*1.0/samplesPerFrame);
    updatePixels();

    saveFrame("f###.gif");
    if (frameCount==numFrames)
      exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 4;
int numFrames = 180;        
float shutterAngle = .6;

boolean recording = false;

void setup() {
  size(540, 540, P3D);
  smooth(8);
  result = new int[width*height][3];
  rectMode(CENTER);
  fill(32);
  noStroke();
}

float x, y, z, tt;
int N = 16;
float r = 120, th;

void slice(float q) {
  push();
  rotate(PI/3);
  push();
  translate(0, -r/sqrt(3));
  tri(q);
  pop();
  push();
  rotate(TWO_PI/3);
  translate(0, -r/sqrt(3));
  tri(1-q);
  pop();
  pop();
}

void tri(float q) {
  beginShape();
  vertex(0, 0);
  for (int i=0; i<=N; i++) {
    th = map(i, 0, N, -PI/6, PI/6);
    x = r*sin(th);
    y = -lerp(-r*mn, -r*cos(th), q);
    vertex(x, y);
  }
  endShape(CLOSE);
}

void draw_() {
  background(250); 
  push();
  translate(width/2, height/2);
  for (int i=0; i<6; i++) {
    tt = (t*5/6 + 1 - i/6.0) % 1;
    tt = constrain(2.75*tt,0,1);
    push();
    rotate(TWO_PI*(i+t)/6);
    y = map(cos(TWO_PI*tt), 1, -1, 0, 1);
    y = -75*ease(y,1);
    translate(0, -r/sqrt(3) + y);
    rotate(TWO_PI*ease(tt, 2.2)/3);
    slice(ease(tt));
    pop();
  }
  pop();
}