flower thing

gistfile1.pde

// by dw

int[][] result;
float t;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3);

void setup() {
  setup_();
  result = new int[width*height][3];
}

void draw() {
  
  if(!recording){
    t = mouseX*1.0/width;
    draw_();
  }
  
  else {
  for (int i=0; i<width*height; i++)
    for (int a=0; a<3; a++)
      result[i][a] = 0;

  for (int sa=0; sa<samplesPerFrame; sa++) {
    t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
    draw_();
    loadPixels();
    for (int i=0; i<pixels.length; i++) {
      result[i][0] += pixels[i] >> 16 & 0xff;
      result[i][1] += pixels[i] >> 8 & 0xff;
      result[i][2] += pixels[i] & 0xff;
    }
  }

  loadPixels();
  for (int i=0; i<pixels.length; i++)
    pixels[i] = 0xff << 24 | 
      int(result[i][0]*1.0/samplesPerFrame) << 16 | 
      int(result[i][1]*1.0/samplesPerFrame) << 8 | 
      int(result[i][2]*1.0/samplesPerFrame);
  updatePixels();

  saveFrame("f###.gif");
  if (frameCount==numFrames)
    exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 8;
int numFrames = 144;        
float shutterAngle = .6;

boolean recording = true;

void setup_() {
  size(500,500,P2D);
  rectMode(CENTER);
  fill(255.0/N);
  smooth(8);
  noStroke();
  blendMode(ADD);
}

float x, y, tt;
int N = 10;
float d = 275;

void draw_() {
  x = map(cos(TWO_PI*t),1,-1,0,1);
  x = 70*ease(x,3.5);
  background(0); 
  pushMatrix();
  translate(width/2, height/2);
  for(int i=0; i<N; i++){
    pushMatrix();
    rotate(TWO_PI*i/N);
    ellipse(x,0,d,d);
    popMatrix();
  }
  popMatrix();
}