raindrops on a pond

drops.pde

// drops, by dave w @beesandbombs >:)

int[][] result;
float t, c;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3);

void setup() {
  setup_();
  result = new int[width*height][3];
}

void draw() {

  if (!recording) {
    t = mouseX*1.0/width;
    c = mouseY*1.0/height;
    if (mousePressed)
      println(c);
    draw_();
  } else {
    for (int i=0; i<width*height; i++)
      for (int a=0; a<3; a++)
        result[i][a] = 0;

    c = 0;
    for (int sa=0; sa<samplesPerFrame; sa++) {
      t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
      draw_();
      loadPixels();
      for (int i=0; i<pixels.length; i++) {
        result[i][0] += pixels[i] >> 16 & 0xff;
        result[i][1] += pixels[i] >> 8 & 0xff;
        result[i][2] += pixels[i] & 0xff;
      }
    }

    loadPixels();
    for (int i=0; i<pixels.length; i++)
      pixels[i] = 0xff << 24 | 
        int(result[i][0]*1.0/samplesPerFrame) << 16 | 
        int(result[i][1]*1.0/samplesPerFrame) << 8 | 
        int(result[i][2]*1.0/samplesPerFrame);
    updatePixels();

    saveFrame("f###.gif");
    if (frameCount==numFrames)
      exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 8;
int numFrames = 222;        
float shutterAngle = .6;

boolean recording = true;

void setup_() {
  size(540, 500, P3D);
  rectMode(CENTER);
  stroke(255);
  noFill();
  smooth(8);
  strokeWeight(2);
}

float x, y, tt;
int N = 5;
float thr = .2;
float dl = 60, dll;
float hei = 450;

void drop(float q) {
  stroke(255);
  strokeWeight(2);
  tt = map(q, 0, thr, 0, 1);
  dll = dl*tt;
  y = hei*tt*tt - hei;
  if (y-dll<0){
    stroke(255);
    line(0, min(0, y-dll), 0, min(0, y));
    strokeWeight(4);
    stroke(42);
    line(0, -min(0, y-dll), 0, -min(0, y));
  }
  if (q >= thr) {
    tt = map(q, thr, 1, 0, 1);
    stroke(constrain(map(tt, 0, 1, 400, -100),0,255));
    strokeWeight(lerp(2, 1, tt));
    pushMatrix();
    translate(0,1*tt,0);
    rotateX(HALF_PI);
    ellipse(0, 0, 360*sqrt(tt), 360*sqrt(tt));
    popMatrix();
  }
}

float qq;

void draw_() {
  println(t);
  background(0); 
  pushMatrix();
  translate(width/2, height/2 - 40, -240);
  rotateX(-.65);

  for (int i=0; i<12; i++) {
    qq = t + i/float(12);
    qq %= 1;
    qq = constrain(1.1*qq,0,1);
    pushMatrix();
    rotateY(TWO_PI*i/12);
    translate(220, 0, 0);
    drop(qq);
    popMatrix();
  }
  popMatrix();
}