spinning dots — http://tmblr.co/ZOLwww1Ml6472

gistfile1.pde

int[][] result;
float t;

void setup() {
  setup_();
  result = new int[width*height][3];
}

void draw() {

  if (!recording) {
    t = mouseX*1.0/width;
    draw_();
  } else {
    for (int i=0; i<width*height; i++)
      for (int a=0; a<3; a++)
        result[i][a] = 0;

    for (int sa=0; sa<samplesPerFrame; sa++) {
      t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
      draw_();
      loadPixels();
      for (int i=0; i<pixels.length; i++) {
        result[i][0] += pixels[i] >> 16 & 0xff;
        result[i][1] += pixels[i] >> 8 & 0xff;
        result[i][2] += pixels[i] & 0xff;
      }
    }

    loadPixels();
    for (int i=0; i<pixels.length; i++)
      pixels[i] = color((result[i][0]/float(samplesPerFrame)),
        (result[i][1]/float(samplesPerFrame)),(result[i][2]/float(samplesPerFrame)));
    updatePixels();

    saveFrame("f###.gif");
    if (frameCount==numFrames)
      exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 16;
int numFrames = 100;        
float shutterAngle = .8;

boolean recording = false;

void setup_() {
  size(500, 500);
  noStroke();
  smooth(8);
}

int N = 21, M;
float r;

void draw_() {
  background(248);
  fill(32);
  pushMatrix();
  translate(width/2,height/2);
  for (int i=0; i<N; i++) {
    r = map(i, N-1, .3, 230, 0);
    M = 3*i;
    for (int j=0; j<M; j++) {
      pushMatrix();
      rotate((j+(N-i)*t)*TWO_PI/M);
      ellipse(r, 0, 5+1.5*i/N, 5+1.5*i/N);
      popMatrix();
    }
  }
  popMatrix();
}