title

readme.txt

Play this game by pasting the script in http://www.puzzlescript.net/editor.html

script.txt

title Add Man
author Adam Gashlin
homepage gashlin.net

key_repeat_interval 0.5
noaction

========
OBJECTS
========

Background
Green

Zero
White
.....
.000.
.0.0.
.000.
.....

ZeroGoal
Blue DarkBlue
00000
01110
01010
01110
00000

One
White
.....
..0..
..0..
..0..
.....

OneGoal
Blue DarkBlue
00000
00100
00100
00100
00000

Player
LightBlue
.....
..0..
.000.
..0..
.....

Wall
Grey

=======
LEGEND
=======

. = Background
P = Player
0 = Zero
O = ZeroGoal
1 = One
! = OneGoal
# = Wall

=======
SOUNDS
=======

================
COLLISIONLAYERS
================

Background
ZeroGoal, OneGoal, Wall
Player, Zero, One

======
RULES
======

[ > Player | Wall ] -> [ Player | Wall ]
[ > Player | Zero ] -> [ > Player | > Zero ]
[ > Player | One ] -> [ > Player | > One ]
[ > Zero | Zero ] -> [ > Zero | ]
[ > Zero | One ] -> [ > One | ]
[ > One | Zero ] -> [ > One | ]
[ > One | One ] -> [ > Zero | > One ]

==============
WINCONDITIONS
==============

All ZeroGoal on Zero
All OneGoal on One

=======
LEVELS
=======

P#O
.#.
1#.
..0
!..

.#...
..11.
.#..!
P#..O

.#.....
!#.1.1P
.#.....

.1...
O1..P
.1...

=.#...
=P#1!.
=.#...
=..0O.
=.....

=#......
=#11111P
=###....
=!##....

=00000
=0010!
=01P10
=00100
=00000

#....
#111P
##...
!#...

..!O!..
.1.1.1.
...P...
.1.1.1.
..O!O..