quarters · http://tmblr.co/ZOLwww1UceCsq

gistfile1.pde

int[][] result;
float t;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3);

void setup() {
  setup_();
  result = new int[width*height][3];
}

void draw() {

  if (!recording) {
    t = mouseX*1.0/width;
    draw_();
  } else {
    for (int i=0; i<width*height; i++)
      for (int a=0; a<3; a++)
        result[i][a] = 0;

    for (int sa=0; sa<samplesPerFrame; sa++) {
      t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
      draw_();
      loadPixels();
      for (int i=0; i<pixels.length; i++) {
        result[i][0] += pixels[i] >> 16 & 0xff;
        result[i][1] += pixels[i] >> 8 & 0xff;
        result[i][2] += pixels[i] & 0xff;
      }
    }

    loadPixels();
    for (int i=0; i<pixels.length; i++)
      pixels[i] = 0xff << 24 | 
        int(result[i][0]*1.0/samplesPerFrame) << 16 | 
        int(result[i][1]*1.0/samplesPerFrame) << 8 | 
        int(result[i][2]*1.0/samplesPerFrame);
    updatePixels();

    saveFrame("f###.gif");
    if (frameCount==numFrames)
      exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 8;
int numFrames = 190;        
float shutterAngle = .6;

boolean recording = true;

void setup_() {
  size(500, 500,P2D);
  smooth(8);
  rectMode(CENTER);
  fill(32);
  noStroke();
}

float x, y, tt;
int N = 32;
float r = 24, sp = 4.5*r;

void quarter(float q) {
  beginShape();
  for (int i=0; i<=N; i++) {
    x = map(i, 0, N, -r*sqrt(.5), r*sqrt(.5));
    y = lerp(-sqrt(r*r - x*x), abs(x)-r, q);
    vertex(x, y);
  }
  for (int i=0; i<=N; i++) {
    x = map(i, N, 0, -r*sqrt(.5), r*sqrt(.5));
    y = lerp(-abs(x), sqrt(r*r-x*x)-r, q);
    vertex(x, y);
  }
  endShape();
}

void full(float q) {
  for (int i=0; i<4; i++) {
    pushMatrix();
    rotate(HALF_PI*i);
    translate(0,lerp(.5,-.5*(sp-2*r)-.5,ease(q,2)));
    quarter(ease(q,3));
    popMatrix();
  }
}

void draw_() {
  background(250); 
  pushMatrix();
  translate(width/2, height/2);
  for (int i=-6; i<=6; i++) {
    for (int j=-6; j<=6; j++) {
      x = i*sp;
      y = j*.5*sp;
      if(j%2 != 0)
        x += .5*sp;
      tt = map(cos(TWO_PI*t - 0.004*dist(x,y,0,0)),1,-1,0,1);
      pushMatrix();
      translate(x, y);
      full(tt);
      popMatrix();
    }
  }
  popMatrix();
}