title

readme.txt

Play this game by pasting the script in http://www.puzzlescript.net/editor.html

script.txt

title Snakebird Demake
author Alan Hazelden
homepage www.draknek.org

norepeat_action

========
OBJECTS
========

Background
blue

CornerTL
Blue
0....
.....
.....
.....
.....

CornerTR
Blue
....0
.....
.....
.....
.....

CornerBL
Blue
.....
.....
.....
.....
0....

CornerBR
Blue
.....
.....
.....
.....
....0

HeadUp
Red Black
.1.1.
.010.
00000
00000
00000

HeadDown
Red Black
00000
00000
00000
.010.
.1.1.

HeadLeft
Red Black
..000
10000
.1000
10000
..000

HeadRight
Red Black
000..
00001
0001.
00001
000..

BodyUp
Red

BodyDown
Red

BodyLeft
Red

BodyRight
Red

TailUp
Red
00000
00000
00000
00000
.000.

TailDown
Red
.000.
00000
00000
00000
00000

TailLeft
Red
0000.
00000
00000
00000
0000.

TailRight
Red
.0000
00000
00000
00000
.0000

Wall
White

Falling
transparent


=======
LEGEND
=======

. = Background

Corner = CornerTL or CornerTR or CornerBL or CornerBR

Head = HeadUp or HeadDown or HeadLeft or HeadRight
Body = BodyUp or BodyDown or BodyLeft or BodyRight
Tail = TailUp or TailDown or TailLeft or TailRight

ConnectedLeft = HeadRight or BodyLeft or TailLeft
ConnectedRight = HeadLeft or BodyRight or TailRight
ConnectedUp = HeadDown or BodyUp or TailUp
ConnectedDown = HeadUp or BodyDown or TailDown

Snake = Head or Body or Tail

Solid = Snake or Wall

R = HeadUp
B = BodyUp
T = TailUp
# = Wall

Player = Head


=======
SOUNDS
=======


================
COLLISIONLAYERS
================

Falling
Background
Snake
Wall, Corner

======
RULES
======

[ stationary Player ] [ Snake ] -> [ Player ] [ Falling Snake ]

startloop
down [ Falling Snake | Solid no Falling ] -> [ Snake | Solid ]

left [ ConnectedLeft Falling | no Falling ] -> [ ConnectedLeft | ]
left [ Falling | ConnectedRight no Falling ] -> [ | ConnectedRight ]

right [ ConnectedRight Falling | no Falling ] -> [ ConnectedRight | ]
right [ Falling | ConnectedLeft no Falling ] -> [ | ConnectedLeft ]

up [ ConnectedUp Falling | no Falling ] -> [ ConnectedUp | ]
up [ Falling | ConnectedDown no Falling ] -> [ | ConnectedDown ]

down [ ConnectedDown Falling | no Falling ] -> [ ConnectedDown | ]
down [ Falling | ConnectedUp no Falling ] -> [ | ConnectedUp ]
endloop

[ action Head ] -> [ Head ]

[ > Head | Solid ] -> cancel

left [ > Head | no Solid ] -> [ BodyLeft | action HeadLeft ]
right [ > Head | no Solid ] -> [ BodyRight | action HeadRight ]
up [ > Head | no Solid ] -> [ BodyUp | action HeadUp ]
down [ > Head | no Solid ] -> [ BodyDown | action HeadDown ]

[ action Head ] [ Tail ] -> [ Head ] [ action Tail ] again

left [ action TailLeft | Body ] -> [ | action Body ]
right [ action TailRight | Body ] -> [ | action Body ]
up [ action TailUp | Body ] -> [ | action Body ]
down [ action TailDown | Body ] -> [ | action Body ]

[ action BodyLeft ] -> [ TailLeft ]
[ action BodyRight ] -> [ TailRight ]
[ action BodyUp ] -> [ TailUp ]
[ action BodyDown ] -> [ TailDown ]

[ Falling Snake ] -> [ down Snake ] again

(corners)

[ Corner ] -> []

late right [ ConnectedDown | ConnectedLeft ] -> [ CornerTL ConnectedDown | ConnectedLeft ]
late right [ ConnectedUp | ConnectedLeft ] -> [ CornerBL ConnectedUp | ConnectedLeft ]

late right [ ConnectedRight | ConnectedDown ] -> [ ConnectedRight | ConnectedDown CornerTR ]
late right [ ConnectedRight | ConnectedUp ] -> [ ConnectedRight | ConnectedUp CornerBR ]

late down [ ConnectedLeft | ConnectedUp ] -> [ CornerTR ConnectedLeft | ConnectedUp ]
late down [ ConnectedRight | ConnectedUp ] -> [ CornerTL ConnectedRight | ConnectedUp ]

late down [ ConnectedDown | ConnectedLeft ] -> [ ConnectedDown | ConnectedLeft CornerBR ]
late down [ ConnectedDown | ConnectedRight ] -> [ ConnectedDown | ConnectedRight CornerBL ]

==============
WINCONDITIONS
==============



=======
LEVELS
=======

.............
......R......
......B......
......B......
......B......
......B......
......T......
#############