title

readme.txt

Play this game by pasting the script in http://www.puzzlescript.net/editor.html

script.txt

title SuperSneezer
author Alan Hazelden
homepage www.draknek.org

(verbose_logging)

(again_interval 1)

norepeat_action

again_interval 0.1

run_rules_on_level_start

========
OBJECTS
========

Background
#dddddd #dddddd
00000
00000
01110
01110
01110

Target
Red #dddddd
.....
10001
00000
00000
00000

BelowTarget
Red #dddddd
10001
.....
.....
.....
.....

Wall
#c4c692

BelowWall
#acad80
00000
.....
.....
.....
.....

AboveWall
#93815f
.....
.....
.....
.....
00000

WallD
#93815f #acad80
.....
.....
.....
00000
11111

WallL
#93815f
0....
0....
0....
0....
0....

WallR
#93815f
....0
....0
....0
....0
....0

WallLR
#93815f
0...0
0...0
0...0
0...0
0...0

AboveWallL
#93815f
.....
.....
.....
0....
0....

AboveWallR
#93815f
.....
.....
.....
....0
....0

PlayerNormal
Black Orange Green Blue
.000.
.111.
22222
.333.
.3.3.

PlayerSneezing
Black Orange Green Blue
.000.
.212.
.222.
.333.
.3.3.

PlayerSweeping
Black Orange Green Blue
.000.
.111.
2220.
.330.
.3000

Crate
DarkGreen Green
.111.
.101.
.111.
.000.
.000.

Dust
Grey
.....
..0..
.0...
....0
..0..

DustFromUL
Grey
.0...
0....
.....
.....
.....

DustFromDL
Grey
.....
.....
.....
0....
.0...

DustFromUR
Grey
...0.
....0
.....
.....
.....

DustFromDR
Grey
.....
.....
.....
....0
...0.

DustOnTarget
#8e1c26
.....
..0..
.0...
....0
..0..

WindU
#cccccc
.....
.000.
0...0
.....
.....

WindD
#cccccc
.....
.....
0...0
.000.
.....
 
WindL
#cccccc
.....
..0..
.0...
.0...
..0..
 
WindR
#cccccc
.....
..0..
...0.
...0.
..0..

Sneezing
transparent


=======
LEGEND
=======

. = Background
# = Wall
P = PlayerNormal
* = Crate
@ = Crate and Target
O = Target
! = Dust

Wind = WindU or WindD or WindL or WindR

Solid = Wall or Crate

Player = PlayerNormal or PlayerSweeping or PlayerSneezing

AboveDecoration = AboveWall or AboveWallL or AboveWallR or WallL or WallR or WallLR
BelowDecoration = BelowWall or BelowTarget

DustAppear = DustFromDL or DustFromDR or DustFromUL or DustFromUR

=======
SOUNDS
=======

(Crate MOVE 36772507)
Undo 39917707
Restart 70281108
Player Move 90515707
Sneezing Create 637902
DustAppear Create 55470102
EndLevel 5598308
CloseMessage 88964107
sfx0 821707 (toggle)
sfx1 62700107 (sweeping)

================
COLLISIONLAYERS
================

Background
BelowDecoration
Wind
Target
Dust, Sneezing, DustAppear
DustOnTarget
Player, Wall, Crate
AboveDecoration
WallD

======
RULES
======

(3D)

([ AboveDecoration ] -> []
[ BelowDecoration ] -> [])

down [ Wall | no Wall ] -> [ Wall WallD | BelowWall ]
up [ Wall | no Wall ] -> [ Wall | AboveWall ]
left [ Wall | no Wall ] -> [ Wall WallL | ]
right [ Wall WallL | no Wall ] -> [ Wall WallLR | ]
right [ Wall no AboveDecoration | no Wall ] -> [ Wall WallR | ]

up [ WallL | Wall no AboveDecoration ] -> [ WallL | Wall AboveWallL ]
up [ WallR | Wall no AboveDecoration ] -> [ WallR | Wall AboveWallR ]

down [ Target | no Wall ] -> [ Target | BelowTarget ]

(Toggle state)

[ action PlayerNormal ] -> [ PlayerSweeping ] sfx0 again
[ action PlayerSweeping ] -> [ PlayerNormal ] sfx0 again

(Sweeping)

[ > PlayerSweeping | Dust ] -> [ > PlayerSweeping | > Dust ] sfx1

[ > Dust | Solid ] -> [ | Solid ]
[ > Dust | Dust ] -> [ | Dust ]

(Wind)

[ WindU ] -> [ up WindU ]
[ WindD ] -> [ down WindD ]
[ WindL ] -> [ left WindL ]
[ WindR ] -> [ right WindR ]

[ > Wind | no Solid | Crate | Solid ] -> [ | | Crate | Solid ]

[ moving Wind ] -> again

[ > Wind | Crate ] -> [ > Wind | > Crate ]

[ > Wind | Wall ] -> [ | Wall ]

[ > Crate | Solid ] -> [ action Crate | Solid ]

[ DustAppear ] -> [ Dust ]

[ action Crate | no Wall no Wind ] -> [ action Crate | action Dust no Wind ]
[ action Crate | no Wall moving Wind ] -> [ action Crate moving Wind | ]

late [ Crate Dust ] -> [ Crate ]

(Animated dust appearing)

down [ action Dust | action Crate left Wind ] -> [ DustFromDL | action Crate left Wind ]
down [ action Dust | action Crate right Wind ] -> [ DustFromDR | action Crate right Wind ]

up [ action Dust | action Crate left Wind ] -> [ DustFromUL | action Crate left Wind ]
up [ action Dust | action Crate right Wind ] -> [ DustFromUR | action Crate right Wind ]

left [ action Dust | action Crate up Wind ] -> [ DustFromUL | action Crate up Wind ]
left [ action Dust | action Crate down Wind ] -> [ DustFromDL | action Crate down Wind ]

right [ action Dust | action Crate up Wind ] -> [ DustFromUR | action Crate up Wind ]
right [ action Dust | action Crate down Wind ] -> [ DustFromDR | action Crate down Wind ]

[ action Crate Wind ] -> [ Crate ]

(Sneezing)

late [ PlayerSneezing ] -> [ Sneezing PlayerNormal ] again

late [ Player Dust ] -> [ PlayerSneezing ] again

late [ Sneezing Player | | Crate | Solid ] -> [ Sneezing Player | Sneezing | Crate | Solid ]

late [ Sneezing Player | Crate | no Solid ] -> [ Sneezing Player | | Crate no Dust ]

late up [ Sneezing Player | no Solid ] -> [ Sneezing Player | WindU ]
late down [ Sneezing Player | no Solid ] -> [ Sneezing Player | WindD ]
late left [ Sneezing Player | no Solid ] -> [ Sneezing Player | WindL ]
late right [ Sneezing Player | no Solid ] -> [ Sneezing Player | WindR ]

late [ Sneezing ] -> [ no Wind ]

late [ Wind Dust ] -> [ Wind ]

(Update graphics)

late [ Dust Target no DustOnTarget ] -> [ Dust Target DustOnTarget ]
late [ no Dust Target DustOnTarget ] -> [ Target ]

==============
WINCONDITIONS
==============

All Target on Crate
No Wind

=======
LEVELS
=======

message "I wish I had some way of moving these heavy crates"
message "You know you only get one wish, right?"

##########
#.......o#
#....*...#
#.p.#!...#
#....*...#
#.......o#
##########

#########
#o.....o#
#..*!*..#
#..!!!.p#
#..*!*..#
#o.....o#
#########

message Press space to toggle broom

##########
##o......#
#....*...#
#..!....p#
#....*...#
##o......#
##########

#######
#o....#
#.....#
#.*!*p#
#.....#
#o....#
#######

#######
#p...o#
#...*.#
#..!..#
#.*...#
#o....#
#######

#########
#.o...o.#
##.*!*.##
##..p..##
##..#..##
###...###
#########

#######
#p...o#
#.*.*!#
#..o..#
#.*.*!#
#o!.!o#
#######

message Thanks for playing :)