Robot Framework 7.0 VAR syntax

var_syntax.robot

*** Test Cases ***
Scalar examples
    VAR    ${simple}    variable
    VAR    ${equals} =    this works too
    VAR    ${variable}    value contains ${simple}
    VAR    ${sentence}    This is a bit longer variable value
    ...    that is split into multiple rows.
    ...    These parts are joined with a space.
    VAR    ${multiline}    This is another longer value.
    ...    This time there is a custom separator.
    ...    As the result this becomes a multiline string.
    ...    separator=\n

List examples
    VAR    @{two items}    Robot    Framework
    VAR    @{empty list}
    VAR    @{lot of stuff}
    ...    first item
    ...    second item
    ...    third item
    ...    fourth item
    ...    last item

Dictionary examples
    VAR    &{two items}    name=Robot Framework    url=http://robotframework.org
    VAR    &{empty dict}
    VAR    &{lot of stuff}
    ...    first=1
    ...    second=2
    ...    third=3
    ...    fourth=4
    ...    last=5

Scope example
    VAR    ${local}    local value
    VAR    ${TEST}    test value    scope=TEST
    VAR    ${SUITE}    suite value    scope=SUITE
    VAR    ${GLOBAL}    global value    scope=GLOBAL

IF/ELSE example
    IF    "${ENV}" == "devel"
        VAR    ${address}    127.0.0.1
        VAR    ${name}    demo
    ELSE
        VAR    ${address}    192.168.1.42
        VAR    ${name}    robot
    END

Inline IF
    IF    "${ENV}" == "devel"    VAR    ${name}    demo    ELSE    VAR    ${name}    robot

Dynamic name
    VAR    ${x}    y    # Normal assignment.
    VAR    ${${x}}    z    # Name created dynamically.
    Should Be Equal    ${y}    z