BaseX RESTXQ reading repeated form values

large-form.xqm

(:~
 : JSON form test apb 6dec 2016
 :)

module namespace page = 'form-test';
import module namespace request = "http://exquery.org/ns/request";
declare 
%rest:path("/form2")
%rest:GET
%output:method("html") 
function page:form-get(){
	<form action="/form2" method="POST" >
        <input type="submit"/>
		{for $i in 1 to 20
		 return <div> <h1>Instance {$i}</h1>
					 <label>f1: <input type="text" name="data1"  /></label>
					 <label>f2: <input type="text" name="data2"  /></label>
					 <select name="opt">
					  <option value="xforms">xforms</option>
					  <option value="xquery">xquery</option>
					  <option value="xslt">xslt</option>
					</select> 
				 </div>
		 }
	</form>
};

declare 
%rest:path("/form2")
%rest:POST
%output:method("html") 
function page:form-post(){
  let $names:=request:parameter-names()
  let $size:=count(request:parameter($names[1])) (:number of instances from 1st param, assume all same:)
  let $data:=for $i in 1 to $size 
             return map:merge($names!map:entry(.,request:parameter(.)[$i]))
          

  for $instance  at $i in $data			
  return <div>
           <h1>$data[{$i}]</h1>
	   {serialize($instance,map{"method":"basex"}) (: show map for illustration :) }
         </div>
};