Created using remix-ide: Realtime Ethereum Contract Compiler and Runtime. Load this file by pasting this gists URL or ID at https://remix.ethereum.org/#version=soljson-v0.6.11+commit.5ef660b1.js&optimize=true&runs=200&gist=

vuzeMerkleDistributor...ALMMerkleDistributor.sol

// SPDX-License-Identifier: GPL-3.0
pragma solidity =0.6.11;
import "./IERC20.sol";
import "./MerkleProof.sol";
import "./IALMMerkleDistributor.sol";

contract ALMMerkleDistributor is IALMMerkleDistributor {

    // address of stable coin i.e USDT
    address public immutable override token;  
    address public immutable override owner;
    //alm token_id -> epoch -> merkleRoot
    mapping(uint256 => mapping(uint256 => bytes32)) private merkleRoot;
    
    // merkleRoot -> Uint256 -> Uint256
    // This is a packed array of booleans.
    mapping(bytes32 => mapping(uint256 => uint256)) private claimedBitMap;
    
    constructor(address token_, uint256 token_id_, uint256 epoch_, bytes32 merkleRoot_) public {
        owner = msg.sender;
        token = token_;
        merkleRoot[token_id_][epoch_] = merkleRoot_;
    }

    function getMerkleRoot(uint256 token_id_, uint256 epoch_) public view override returns (bytes32) {
        return merkleRoot[token_id_][epoch_];
    }

    function setMerkleRoot(uint256 token_id_, uint256 epoch_, bytes32 merkleRoot_) external override{
        require(msg.sender == owner, "ALMMerkleDistributor: Only owner can call this function");
        merkleRoot[token_id_][epoch_] = merkleRoot_;
    }

    function isClaimed(uint256 index, bytes32 merkleRoot_) public view override returns (bool) {
        uint256 claimedWordIndex = index / 256;
        uint256 claimedBitIndex = index % 256;
        uint256 claimedWord = claimedBitMap[merkleRoot_][claimedWordIndex];
        uint256 mask = (1 << claimedBitIndex);
        return claimedWord & mask == mask;
    }

    function _setClaimed(uint256 index, bytes32 merkleRoot_) private {
        uint256 claimedWordIndex = index / 256;
        uint256 claimedBitIndex = index % 256;
        claimedBitMap[merkleRoot_][claimedWordIndex] = claimedBitMap[merkleRoot_][claimedWordIndex] | (1 << claimedBitIndex);
    }

    function claim(uint256 index, address account, uint256 amount, bytes32[] calldata merkleProof, bytes32 merkleRoot_) external override {
        require(!isClaimed(index, merkleRoot_), 'MerkleDistributor: Drop already claimed.');

        // Verify the merkle proof.
        bytes32 node = keccak256(abi.encodePacked(index, account, amount));
        require(MerkleProof.verify(merkleProof, merkleRoot_, node), 'MerkleDistributor: Invalid proof.');

        // Mark it claimed and send the token.
        _setClaimed(index, merkleRoot_);
        require(IERC20(token).transfer(account, amount), 'MerkleDistributor: Transfer failed.');

        // specific emit emision? i.e do we add token_id 
        emit Claimed(index, account, amount);
    }
}

vuzeMerkleDistributor...IALMMerkleDistributor.sol

// SPDX-License-Identifier: UNLICENSED
pragma solidity =0.6.11;
// Allows anyone to claim a token if they exist in a merkle root.
interface IALMMerkleDistributor {
    // Returns the address of the token distributed by this contract.
    function token() external view returns (address);
    // Returns the address of the owner of this contract.
    function owner() external view returns (address);
    // Returns true if the index has been marked claimed.
    function isClaimed(uint256 index, bytes32 merkleRoot_) external view returns (bool);
    // Claim the given amount of the token to the given address. Reverts if the inputs are invalid.
    function claim(uint256 index, address account, uint256 amount, bytes32[] calldata merkleProof, bytes32 merkleRoot_) external;
    // Sets the merkleRoot
    function setMerkleRoot(uint256 token_id_, uint256 epoch_, bytes32 merkleRoot_) external; 
    // Returns the merkleRoot
    function getMerkleRoot(uint256 token_id_, uint256 epoch_) external view returns (bytes32);
    // This event is triggered whenever a call to #claim succeeds.
    event Claimed(uint256 index, address account, uint256 amount);
}

vuzeMerkleDistributor...IERC20.sol

// SPDX-License-Identifier: MIT

pragma solidity >=0.6.0 <0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `recipient`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address recipient, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `sender` to `recipient` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address sender, address recipient, uint256 amount) external returns (bool);

    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);
}

vuzeMerkleDistributor...MerkleProof.sol

// SPDX-License-Identifier: MIT

pragma solidity >=0.6.0 <0.8.0;

/**
 * @dev These functions deal with verification of Merkle trees (hash trees),
 */
library MerkleProof {
    /**
     * @dev Returns true if a `leaf` can be proved to be a part of a Merkle tree
     * defined by `root`. For this, a `proof` must be provided, containing
     * sibling hashes on the branch from the leaf to the root of the tree. Each
     * pair of leaves and each pair of pre-images are assumed to be sorted.
     */
    function verify(bytes32[] memory proof, bytes32 root, bytes32 leaf) internal pure returns (bool) {
        bytes32 computedHash = leaf;

        for (uint256 i = 0; i < proof.length; i++) {
            bytes32 proofElement = proof[i];

            if (computedHash <= proofElement) {
                // Hash(current computed hash + current element of the proof)
                computedHash = keccak256(abi.encodePacked(computedHash, proofElement));
            } else {
                // Hash(current element of the proof + current computed hash)
                computedHash = keccak256(abi.encodePacked(proofElement, computedHash));
            }
        }

        // Check if the computed hash (root) is equal to the provided root
        return computedHash == root;
    }
}