Install.cmd

@echo off
set winsd=%~dp0
set winsd=%winsd:~0,-1%
echo %winsd%

:: BatchGotAdmin
:-------------------------------------
REM  --> Check for permissions
    IF "%PROCESSOR_ARCHITECTURE%" EQU "amd64" (
>nul 2>&1 "%SYSTEMROOT%\SysWOW64\cacls.exe" "%SYSTEMROOT%\SysWOW64\config\system"
) ELSE (
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
)

REM --> If error flag set, we do not have admin.
if '%errorlevel%' NEQ '0' (
    echo Requesting administrative privileges...
    goto UACPrompt
) else ( goto gotAdmin )

:UACPrompt
    echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
    set params= %*
    echo UAC.ShellExecute "cmd.exe", "/c ""%~s0"" %params:"=""%", "", "runas", 1 >> "%temp%\getadmin.vbs"

    "%temp%\getadmin.vbs"
    del "%temp%\getadmin.vbs"
    exit /B

:gotAdmin
    pushd "%CD%"
    CD /D "%~dp0"
:--------------------------------------    

REM This installation script should be run in saved copy of Windows 10 Update Software Distribution folder

echo This script will install Windows Feature Update located in this directory.
echo Your computer will automatically restart.
echo.
echo Setting up update environment...
start /w %winsd%\WindowsUpdateBox.exe /Package /PreDownload
echo.
echo Installing Windows Feature Update...
start /w %winsd%\WindowsUpdateBox.exe /Package /Install /ActionListFile ActionList.xml
echo Installation finished!
echo.
echo Performing post-installation...
start /w %winsd%\WindowsUpdateBox.exe /Package /Finalize /ActionListFile ActionList.xml