job.nix

{ pkgs, lib, config, ... }:
let
  cfg = config.webshop;
in
{
  options.webshop = {
    website = lib.mkOption {
      type = lib.types.package;
      description = "The static content to serve";
    };
  };

  config.job.webshop = {
    datacenters = [ "dc1" ];
    group.webserver = {
      network.port.http = {};
      task.webserver.nix.script = "cd ${cfg.website} && ${pkgs.python3}/bin/python -m http.server $NOMAD_PORT_http";
    };
    group.database = {
      volume.pgdata = { type = "host"; source = "pgdata"; };
      network.port.postgres = {};
      task.postgres =
        let
          pgdata = "/pgdata/pgdata";
        in
          {
            resources.memory = 2000;
            volume_mount = [ { volume = "pgdata"; destination = "/pgdata"; } ];
            env.PGDATA = pgdata;
            nix.script = ''
              mkdir -p /alloc/pgtmp
              test -e ${pgdata}/PG_VERSION || ${pkgs.postgresql}/bin/initdb --no-locale --encoding=UTF8
              exec ${pkgs.postgresql}/bin/postgres -p $NOMAD_PORT_postgres -k /alloc/pgtmp
            '';
          };
    };
  };
}