Автоматическая распаковка дистрибутивов конфигураций 1C 7.7. Позволяет распаковывать 16 разрядные установщики на 64 разрядных ОС.

extract-w7.cmd

@echo off
echo Автоматическая распаковка дистрибутивов конфигураций 7.7
echo --------------------------------------------------------
echo (c) 2012, Decker, andrewks
rem http://dml.compkaluga.ru/forum/index.php?showtopic=54199
rem необходим распаковщик STIX
rem (http://www.kannegieser.net/veit/quelle/stix_src.arj)
rem более шустрая версия для Windows 7 и выше
rem создаёт символические ссылки вместо копирования файлов
rem mklink требует админа

if "%1"=="admin" goto admin
set __COMPAT_LAYER=RunAsAdmin 
start /B "" cmd.exe /c %0 admin
goto EOF

:admin
%~d0
cd %~dp0

FOR /r %%c in (std*.z) do echo %%~nxc >> files.lst
FOR /r %%c in (std*.1) do echo %%~nxc >> files.lst
FOR /r %%c in (std*.??) do echo %%~nxc >> files.lst
 
FOR /r %%c in (std*.??) do mklink %%~nxc "%%~dpnxc"
 
FOR /F "tokens=1" %%i IN (files.lst) DO stix_w32.exe %%~nxi unp 
FOR /F "tokens=1" %%i IN (files.lst) DO del %%~nxi /q
del files.lst /q

:EOF

extract.cmd

@echo off
echo Автоматическая распаковка дистрибутивов конфигураций 7.7
echo --------------------------------------------------------
echo (c) 2012, Decker, andrewks
rem http://dml.compkaluga.ru/forum/index.php?showtopic=54199
rem необходим распаковщик STIX
rem (http://www.kannegieser.net/veit/quelle/stix_src.arj)
 
FOR /r %%c in (std*.z) do echo %%~nxc >> files.lst
FOR /r %%c in (std*.1) do echo %%~nxc >> files.lst
FOR /r %%c in (std*.??) do echo %%~nxc >> files.lst
 
FOR /r %%c in (std*.??) do copy "%%~dpnxc" . 
 
FOR /F "tokens=1" %%i IN (files.lst) DO stix_w32.exe %%~nxi unp 
FOR /F "tokens=1" %%i IN (files.lst) DO del %%~nxi /q
del files.lst /q