eks_fluent_bit_original.tf

eks_fluent_bit_original.tf

### AWS Fluent Bit
resource "helm_release" "fluent-bit" {
  name       = "aws-for-fluent-bit"
  repository = "https://aws.github.io/eks-charts"
  chart      = "aws-for-fluent-bit"
  namespace  = var.namespace

  version = var.helm_version

  dependency_update = true

  values = [<<EOF
    image:
      tag: ${var.image_version}
    %{if var.labels != null}
    affinity:
      nodeAffinity:
        requiredDuringSchedulingIgnoredDuringExecution:
          nodeSelectorTerms:
          - matchExpressions:
            - key: pool
              operator: In
              values:
              %{for label in var.labels}
              - ${label}
              %{endfor}
    tolerations:
      %{for label in var.labels}
      - key: dedicated
        operator: Equal
        value: ${label}
        effect: NoSchedule
      %{endfor}
    %{endif}
    rbac:
      pspEnabled: ${var.rbac_psp_enabled}
    serviceAccount:
      create: false
      name: ${kubernetes_service_account.irsa.metadata[0].name}
    cloudWatchLogs:
      enabled: false
    firehose:
      enabled: false
    kinesis:
      enabled: false
    elasticsearch:
      enabled: false
    opensearch:
      enabled: true
      match: ${var.opensearch_filter}.*
      host: ${var.opensearch_host}
      port: "443"
      awsRegion: ${var.aws_region}
      awsAuth: "Off"
      logstashFormat: "on"
      logstashPrefix: ${var.logstash_prefix}
      logstashPrefixKey: Index
    input:
      extraInputs: |
        Exclude_Path      /var/log/containers/aws-for-fluent-bit*,/var/log/containers/${var.opensearch_filter}*
    additionalInputs: |
      [INPUT]
          Name              tail
          Tag               ${var.opensearch_filter}.*
          Path              /var/log/containers/${var.opensearch_filter}*.log
          DB                /var/log/flb_kube.db
          multiline.parser  docker,cri
          Docker_Mode       Off
          Mem_Buf_Limit     50MB
          Skip_Long_Lines   Off
          Refresh_Interval  10
    additionalFilters: |
      [FILTER]
          Name                kubernetes
          Match               ${var.opensearch_filter}.*
          Kube_URL            https://kubernetes.default.svc.cluster.local:443
          Merge_Log           On
          Keep_log            Off
          K8S-Logging.Parser  On
          K8S-Logging.Exclude On
          Kube_Tag_Prefix     kube.${var.opensearch_filter}.log.containers.
          Labels              Off
          Annotations         Off
      [FILTER]
          Name                nest
          Match               ${var.opensearch_filter}.*
          Operation           lift
          Nested_under        kubernetes
          Add_prefix          kubernetes.
      [FILTER]
          Name                record_modifier
          Match               ${var.opensearch_filter}.*
          %{for label in var.opensearch_remove_keys}
          Remove_key          ${label}
          %{endfor}
    EOF
  ]
}