ArchLinux AUR PKGBUILD for rsync-compatible rssh

PKGBUILD (rssh)

# Maintainer: Christian Hesse <[email protected]>
# Contributor: Judd Vinet <[email protected]>
# Contributor: Gaetan Bisson <[email protected]>

pkgname=rssh
pkgver=2.3.4
pkgrel=4
pkgdesc='Restricted secure shell allowing only scp, sftp, cvs, rsync or rdist'
url='http://www.pizzashack.org/rssh/'
license=('custom:rssh')
arch=('i686' 'x86_64' 'armv6h')
backup=('etc/rssh.conf')
depends=('openssh')
source=("http://downloads.sourceforge.net/sourceforge/rssh/rssh-${pkgver}.tar.gz"{,.sig}
	'fail-logging.patch'
	'info-to-debug.patch'
	'man-page-spelling.patch'
	'mkchroot-arch.patch'
	'mkchroot.patch'
	'mkchroot-symlink.patch'
	'destdir.patch'
        'http://pkgs.fedoraproject.org/cgit/rssh.git/plain/rssh-2.3.4-rsync-protocol.patch')

build() {
	cd "${srcdir}/${pkgname}-${pkgver}"

	# from debian package (2.3.3-4)
	# http://ftp.de.debian.org/debian/pool/main/r/rssh/rssh_2.3.3-4.debian.tar.gz

	msg "Patching fail-logging.patch"
	patch -Np1 < ${srcdir}/fail-logging.patch
	msg "Patching info-to-debug.patch"
	patch -Np1 < ${srcdir}/info-to-debug.patch
	msg "Patching man-page-spelling.patch"
	patch -Np1 < ${srcdir}/man-page-spelling.patch
	msg "Patching mkchroot.patch"
	patch -Np1 < ${srcdir}/mkchroot.patch

	msg "Patching mkchroot-arch.patch"
	patch -Np1 < ${srcdir}/mkchroot-arch.patch
	msg "Patching mkchroot-symlink.patch"
	patch -Np1 < ${srcdir}/mkchroot-symlink.patch

	msg "Patching destdir.patch"
	patch -Np1 < ${srcdir}/destdir.patch

        msg "Patching rssh-2.3.4-rsync-protocol.patch"
        patch -Np1 < ${srcdir}/rssh-2.3.4-rsync-protocol.patch

	./configure \
		--prefix=/usr \
		--libexecdir=/usr/lib/rssh \
		--mandir=/usr/share/man \
		--sysconfdir=/etc \

	make
}

package() {
	cd "${srcdir}/${pkgname}-${pkgver}"

	make DESTDIR="${pkgdir}" install
	mv ${pkgdir}/etc/rssh.conf.default ${pkgdir}/etc/rssh.conf

	install -D -m0644 LICENSE "${pkgdir}"/usr/share/licenses/rssh/LICENSE

	install -D -m0755 mkchroot.sh "${pkgdir}"/usr/bin/mkchroot
}

sha256sums=('f30c6a760918a0ed39cf9e49a49a76cb309d7ef1c25a66e77a41e2b1d0b40cd9'
            'SKIP'
            'd30f2f4fdb1b57f94773f5b0968a4da3356b14a040efe69ec1e976c615035c65'
            '86f6ecf34f62415b0d6204d4cbebc47322dc2ec71732d06aa27758e35d688fcd'
            '455b3bbccddf1493999d00c2cd46e62930ef4fd8211e0b7d3a89d8010d6a5431'
            'ac8894c4087a063ae8267d2fdfcde69c2fe6b67a8ff5917e4518b8f73f08ba3f'
            'f7fd8723d2aa94e64e037c13c2f263a52104af680ab52bfcaea73dfa836457c2'
            'bce98728cb9b55c92182d4901c5f9adf49376a07c5603514b0004e3d1c85e9c7'
            '7fa03644f81dc37d77cc7e2cad994f17f91b2b8a49b1a74e41030a4ac764385e'
            '0c772afe9088eeded129ead86775ef18e58c318bbc58fc3e2585e7ff09cc5e91')