metasploit 4.9.3 PKGBUILD

PKGBUILD

# Maintainer: Babken Vardanyan - axper <483ken 4t gma1l
# Contributor: Sabart Otto - Seberm <seberm[at]seberm[dot]com>
# Contributor: Tobias Veit - nIcE <m.on.key.tobi[at]gmail[dot]com>

pkgname=metasploit
pkgver=4.9.3
pkgrel=1
pkgdesc="An advanced open-source platform for developing, testing, and using exploit code"
depends=('ruby1.9' 'libpcap' 'postgresql-libs')
optdepends=('java-runtime: msfgui' 'dradis' 'ruby-pg: database support') #sqlite
provides=('metasploit')
conflicts=('metasploit-git')
options=('!strip')
makedepends=('subversion' 'ruby1.9-bundler')
source=("http://downloads.metasploit.com/data/releases/archive/framework-${pkgver}.tar.bz2")
install=metasploit.install
url="http://www.metasploit.com/"
license=('BSD')
arch=('any')

md5sums=('SKIP')

package() {
  mkdir -p "$pkgdir/usr/share" "$pkgdir/usr/bin"
  install -Dm644 "$srcdir/msf3/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  install -Dm644 "$srcdir/msf3/COPYING" "$pkgdir/usr/share/licenses/$pkgname/COPYING"

  mv "$srcdir/msf3" "$pkgdir/usr/share/$pkgname"

  for f in $pkgdir/usr/share/$pkgname/msf*; do
    local _msffile="$pkgdir/usr/bin/`basename "$f"`"
    echo "ruby-1.9 /usr/share/$pkgname/`basename "$f"` \"\$@\"" > $_msffile
    chmod 755 $_msffile
  done;
}

# vim:set ts=2 sw=2 et: