vimperator-hg PKGBUILD

PKGBUILD

# Maintainer: Michael Witten <mfwitten>
# Contributor: Axpere Jan <483ken _@AT@_ gmail>
# Contributor: Gustavo Dutra <[email protected]>

pkgname=vimperator-hg
pkgver=r4791.4b30fbfb2ee3
pkgrel=1
pkgdesc="Make firefox look and behave like Vim (hg version)"
arch=('any')
url="http://www.vimperator.org/vimperator"
license=('MIT')
groups=('network')
depends=('firefox>=4.0b5')
makedepends=('mercurial' 'zip' 'unzip')
provides=('vimperator')
conflicts=('vimperator')
source=("${pkgname}::hg+https://vimperator-labs.googlecode.com/hg/")
md5sums=('SKIP')


pkgver() {
  cd "${srcdir}/${pkgname}"
  printf "r%s.%s" "$(hg identify -n)" "$(hg identify -i)"
}

build() {
  cd "${srcdir}/${pkgname}/vimperator"
  make xpi
}

package() {
  install -d "${pkgdir}/usr/lib/firefox/browser/extensions/[email protected]"
  cd "${srcdir}/${pkgname}/downloads"
  unzip *.xpi -d "${pkgdir}/usr/lib/firefox/browser/extensions/[email protected]"

  # License
  install -Dm644 "$srcdir/${pkgname}/License.txt" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}

# vim:set ts=2 sw=2 et: