Grammar for my config language

grammar-1.pegjs

// Aziis98 Data Grammar
// ==========================
//

{
    function Symbol(text) {
    	this.__type__ = "Symbol";
    	this.text = text;
    }
}

start
  	= root:PropertyList
  
Value
	= value:(Integer / String / Identifier / List / Object) { return value }
  
Object
	= "{" nl pl:PropertyList "}" { 
    	return pl
    }
  
PropertyList
	= head:(_ KeyValue)? tail:(nl _ KeyValue)* blank {
    	if (head) {
    		return [head[1]].concat(tail.map(prop => prop[2]))
        		.reduce((prop, acc) => Object.assign(acc, prop), {});
        }
        else {
        	return { /* empty object */ };
        }
    }
  
KeyValue
	= KeyValueAssing / KeyList / KeyObject
  
KeyValueAssing
  	= key:Key _ "="? _ value:Value { return { [key]: value } }
KeyList
	= key:Key _ list:List { return { [key]: list } }
KeyObject
	= key:Key _ object:Object { return { [key]: object } }
  
List
	= "[" blank values:( Value blank? ","? blank? )* "]" {
    	return values.map(value => value[0])
    }
  
Key
  	= id:Identifier { return id.text }

Identifier "identifier"
  	= Word ( _ Word)* { return new Symbol(text().trim()) }

Word
	= [^0-9 \t\n\r={}\[\],]+

Integer "integer"
  	= [0-9]+ { return parseInt(text(), 10); }

String "string"
	= '"' string:[^\n"]* '"' { return string.join('') }

blank
	= [ \t\n\r]+ / EOF
    
nl
	= [ \t]*[\n\r] blank

_ "whitespace"
  	= [ \t]*
              
EOF
	= !.