A cfengine bundle to upgrade all or a list of packages on a Debian system.

dpkgup.cf

bundle agent dpkgup(p_list) {

vars:

    done_with_classes.package_list_provided::
        "pkg_list" string => join(" ", p_list), policy => "free";
    done_with_classes.!package_list_provided::
        "pkg_list" string => "", policy => "free";

    done_with_classes::
        "apt_show_versions" string => execresult("/usr/bin/apt-show-versions -u $(pkg_list)","useshell");
        "dim" int => parsestringarray("upgrade","$(apt_show_versions)","NoComments","[/ ]","1000","200000");

        "package" slist => getindices("upgrade");

classes:

    "package_list_provided" expression => isvariable("p_list");
    "done_with_classes" expression => "any";

reports:

    "Upgrade $(package) to $(upgrade[$(package)][6])";

packages:

    "apt-show-versions"
        package_policy => "addupdate",
        handle => canonify("$(this.bundlename)_apt_get_install_$(install)"),
        package_method => apt_get_permissive;

    "$(package)"
        package_policy => "addupdate",
        handle => canonify("$(this.bundlename)_apt_get_install_$(package)"),
        package_method => apt_get,
        package_version => "$(upgrade[$(package)][6])",
        package_select => ">=";

}

yumup.cf

bundle agent rpmup(p_list) {

vars:

    done_with_classes.package_list_provided::
        "pkg_list" string => join(" ", p_list), policy => "free";
    done_with_classes.!package_list_provided::
        "pkg_list" string => "", policy => "free";

    done_with_classes::
        "yum_list_updates" string => execresult("/usr/bin/yum -C list updates $(pkg_list) | grep updates","useshell");
        "dim" int => parsestringarray("upgrade","$(yum_list_updates)","NoComments","\s+","1000","200000");

        "package" slist => getindices("upgrade");
	"p[$(package)]"	slist => splitstring("$(package)","\.","1");

classes:

    "package_list_provided" expression => isvariable("p_list");
    "done_with_classes" expression => "any";

reports:

    "Upgrade $(p[$(package)]) to $(upgrade[$(package)][1])";

packages:

    "$(p[$(package)])"
        package_policy => "addupdate",
        handle => canonify("$(this.bundlename)_yum_install_$(package)"),
        package_method => yum,
        package_version => "$(upgrade[$(package)][1])",
        package_select => ">=";

}

zypperup.cf

bundle agent zypper_up(p_list) {
 
vars:
 
    package_list_provided::
	"pkg_list" slist => { "@(p_list)" };
    done_with_classes::
        "zyp_show_versions" string => execresult("/usr/bin/zypper lu |awk -F \| '$1~/v/{gsub(\" \",\"\"); print $3,$5}NR==80{nextfile}'","useshell");
        "dim" int => parsestringarray("upgrade","$(zyp_show_versions)","NoComments","  *","1000","200000");
 
	"upgradeable" slist => getindices("upgrade");
 
    done_with_classes.package_list_provided::
        "package" slist => intersection("upgradeable", "pkg_list");
    done_with_classes.!package_list_provided::
	"package" slist => { "$(upgradeable)" };
 
 
classes:
 
    "package_list_provided" expression => isvariable("p_list");
    "done_with_classes" expression => "any";
 
reports:
 
    "Upgrade $(package) to $(upgrade[$(package)][1])";
 
packages:
 
any::
    "$(package)"
        package_policy => "update",
        handle => canonify("$(this.bundlename)_install_$(package)"),
        package_method => zypper,
        package_version => "$(upgrade[$(package)][1])",
        package_select => ">=";
 
}

Usage:

bundle agent upgrade_all
{
 methods:
    "upgrade" usebundle => dpkgup;
}

Or

bundle agent upgrade_some
{
 vars:
    "p" slist => { "bash", "zsh" };
 methods:
    "upgrade" usebundle => dpkgup("@(upgrade_some.p)");
}