PKGBUILD for fluent-bit 1.9.2-2

PKGBUILD

# vim: et ts=4 sw=4:
# Maintainer: Joost Molenaar <[email protected]>
# Contributor: Tim Meusel <[email protected]>

pkgname=fluent-bit

pkgver=1.9.2
pkgrel=2
pkgdesc="Collect data/logs from different sources, unify and send them to multiple destinations"
url="https://fluentbit.io/"
arch=(x86_64 aarch64 armv7h i686)
license=('Apache')
depends=('gcc-libs' 'openssl' 'libsystemd.so')
# PostgreSQL_TYPE_INCLUDE_DIR is provided by postgresql, this is currently a bug
makedepends=('cmake' 'postgresql-libs' 'postgresql' 'python' 'valgrind' 'systemd-libs')
checkdepends=('gtest' 'doxygen' 'graphviz')
backup=('etc/fluent-bit/fluent-bit.conf'
        'etc/fluent-bit/parsers.conf'
        'etc/fluent-bit/plugins.conf')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/fluent/${pkgname}/archive/refs/tags/v${pkgver}.tar.gz")

prepare() {
    cd $pkgname-$pkgver
    sed -i -e 's, /lib/systemd/system, /usr/lib/systemd/system,' CMakeLists.txt
    sed -i -e 's, /lib/systemd/system, /usr/lib/systemd/system,' src/CMakeLists.txt
    rm -fr build
    mkdir build
}

build() {
    cd $pkgname-$pkgver/build
    cmake \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DCMAKE_INSTALL_SYSCONFDIR=/etc \
        -DCMAKE_INSTALL_LIBDIR=lib \
        -DSYSTEMD_DIR=/usr/lib/systemd/system \
        -DFLB_TESTS_INTERNAL=Yes \
        -DFLB_IN_MQTT=Yes \
        -DFLB_TLS=Yes \
        -DFLB_ALL=Yes \
        -DFLB_OUT_NATS=Yes \
        -DFLB_HTTP_SERVER=Yes \
        -DMBEDTLS_FATAL_WARNINGS=Off \
        ..
    make
}

check() {
    cd $pkgname-$pkgver/build
    make test
}

package() {
    cd $pkgname-$pkgver/build

    # install binaries and libraries
    make DESTDIR="$pkgdir/" install

    # install license file and documentation
    install -Dm 644 ../LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
    install -Dm 644 ../*.md -t "$pkgdir/usr/share/doc/$pkgname/"
}

md5sums=('fe5cf05f86e0c7766b5118cc6c436d5f')
sha512sums=('d15d6019df5c59bf8442cc32324676bd6e3bccdded1a91b601fc6352a2873a46a3a8880ba4a035fe5b7c6b16f25364638ee6f51923c79fe670dd8bf1706f95a9')
b2sums=('abcffb46dc1d97bdb10285579bc7f6ed0c811cbc4e2fff764a982691dcf259b2952fea960ed66bae5877b4c1b85cb5a0e97fb0e330e1a1be6c5d08a1103e1ca4')