cubes

cubes.pde

int[][] result;
float t, c;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3), ia = atan(sqrt(.5));

void push() {
  pushMatrix();
  pushStyle();
}

void pop() {
  popStyle();
  popMatrix();
}

void draw() {

  if (!recording) {
    t = mouseX*1.0/width;
    c = mouseY*1.0/height;
    if (mousePressed)
      println(c);
    draw_();
  } else {
    for (int i=0; i<width*height; i++)
      for (int a=0; a<3; a++)
        result[i][a] = 0;

    c = 0;
    for (int sa=0; sa<samplesPerFrame; sa++) {
      t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
      draw_();
      loadPixels();
      for (int i=0; i<pixels.length; i++) {
        result[i][0] += pixels[i] >> 16 & 0xff;
        result[i][1] += pixels[i] >> 8 & 0xff;
        result[i][2] += pixels[i] & 0xff;
      }
    }

    loadPixels();
    for (int i=0; i<pixels.length; i++)
      pixels[i] = 0xff << 24 | 
        int(result[i][0]*1.0/samplesPerFrame) << 16 | 
        int(result[i][1]*1.0/samplesPerFrame) << 8 | 
        int(result[i][2]*1.0/samplesPerFrame);
    updatePixels();

    saveFrame("f###.gif");
    if (frameCount==numFrames)
      exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 4;
int numFrames = 300;        
float shutterAngle = .5;

boolean recording = false;

void setup() {
  size(750, 750, P3D);
  smooth(8);
  result = new int[width*height][3];
  rectMode(CENTER);
  fill(32);
  noStroke();
}

float x, y, z, tt;
int N = 12;

color c1 = #59B390, c2 = #F0DDAA, c3 = #152B3C;
float l = 23, r = 120;

void cube() {
  push();
  rotateX(ia);
  rotate(QUARTER_PI);
  for (int i=0; i<4; i++) {
    push();
    fill(c1);
    if (i%2 == 0)
      fill(c2);
    rotateY(HALF_PI*i);
    translate(0, 0, l/2);
    rect(0, 0, l, l);
    pop();
  }

  for (int i=0; i<4; i++) {
    push();
    fill(c3);
    rotateX(HALF_PI+PI*i);
    translate(0, 0, l/2);
    rect(0, 0, l, l);
    pop();
  }
  pop();
}

void ring(float q, float ph) {
  for (int i=0; i<N; i++) {
    push();
    rotate(TWO_PI*i/N);
    translate(0, r, 0);
    rotateY(TWO_PI*q + TWO_PI*(i+ph)/float(N));
    cube();
    pop();
  }
}

void draw_() {
  background(250); 
  push();
  translate(width/2, height/2);
  for (int i=-18; i<8; i++) {
    push();
    scale(pow(1.35,i+2*t));
    if(i%2 == 0)
      rotate(-PI/N);
    ring(t, .5*((i+100)%2));
    pop();
  }
  pop();
}

gif: https://twitter.com/beesandbombs/status/880207906381205505