curlers

curlers.pde

// gif by dave — enjoy! :)

int[][] result;
float t, c;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3), ia = atan(sqrt(.5));

void push() {
  pushMatrix();
  pushStyle();
}

void pop(){
  popStyle();
  popMatrix();
}

void draw() {
  
  if(!recording){
    t = mouseX*1.0/width;
    c = mouseY*1.0/height;
    if(mousePressed)
        println(c);
    draw_();
  }
  
  else {
  for (int i=0; i<width*height; i++)
    for (int a=0; a<3; a++)
      result[i][a] = 0;

  c = 0;
  for (int sa=0; sa<samplesPerFrame; sa++) {
    t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
    draw_();
    loadPixels();
    for (int i=0; i<pixels.length; i++) {
      result[i][0] += pixels[i] >> 16 & 0xff;
      result[i][1] += pixels[i] >> 8 & 0xff;
      result[i][2] += pixels[i] & 0xff;
    }
  }

  loadPixels();
  for (int i=0; i<pixels.length; i++)
    pixels[i] = 0xff << 24 | 
      int(result[i][0]*1.0/samplesPerFrame) << 16 | 
      int(result[i][1]*1.0/samplesPerFrame) << 8 | 
      int(result[i][2]*1.0/samplesPerFrame);
  updatePixels();

  saveFrame("t###.gif");
  if (frameCount==numFrames)
    exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 4;
int numFrames = 180;        
float shutterAngle = .6;

boolean recording = false;

void setup() {
  size(720,720,P3D);
  smooth(8);
  //pixelDensity(2);
  result = new int[width*height][3];
  rectMode(CENTER);
  stroke(32);
  strokeWeight(2.5);
  noFill();
}

float x, y, z, tt;
int N = 720;
float r, th, qq;
int nc;

void thing(float r_, float q){
  N = int(7*r_);
  nc = int(r_*.25);
  beginShape();
  for(int i=0; i<N; i++){
    th = TWO_PI*i/N;
    qq = .5-.5*cos(TWO_PI*q - th);
    r = r_+ease(qq)*14*cos(nc*th + 2*TWO_PI*t);
    th += 0.1*ease(constrain(1.85*qq,0,1))*sin(nc*th + 2*TWO_PI*t)*36/nc;
    x = r*cos(th);
    y = r*sin(th);
    vertex(x,y);
  }
  endShape(CLOSE);
}

void draw_() {
  background(250); 
  push();
  translate(width/2, height/2);
  for(int i=0; i<7; i++)
    thing(40 + 40*i,t + i/12.0);
  pop();
}

gif: https://twitter.com/beesandbombs/status/902646190092800001