triangle spin

triSpin.pde

int[][] result;
float t, c;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3), ia = atan(sqrt(.5));

void push() {
  pushMatrix();
  pushStyle();
}

void pop() {
  popStyle();
  popMatrix();
}

void draw() {

  if (!recording) {
    t = mouseX*1.0/width;
    c = mouseY*1.0/height;
    if (mousePressed)
      println(c);
    draw_();
  } else {
    for (int i=0; i<width*height; i++)
      for (int a=0; a<3; a++)
        result[i][a] = 0;

    c = 0;
    for (int sa=0; sa<samplesPerFrame; sa++) {
      t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
      draw_();
      loadPixels();
      for (int i=0; i<pixels.length; i++) {
        result[i][0] += pixels[i] >> 16 & 0xff;
        result[i][1] += pixels[i] >> 8 & 0xff;
        result[i][2] += pixels[i] & 0xff;
      }
    }

    loadPixels();
    for (int i=0; i<pixels.length; i++)
      pixels[i] = 0xff << 24 | 
        int(result[i][0]*1.0/samplesPerFrame) << 16 | 
        int(result[i][1]*1.0/samplesPerFrame) << 8 | 
        int(result[i][2]*1.0/samplesPerFrame);
    updatePixels();

    saveFrame("f###.gif");
    if (frameCount==numFrames)
      exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 2;
int numFrames = 140;        
float shutterAngle = .4;

boolean recording = false;

void setup() {
  size(720, 720, P3D);
  strokeWeight(3);
  smooth(8);
  result = new int[width*height][3];
  rectMode(CENTER);
  stroke(32);
  noFill();
}

float x, y, z, tt;
float th, r, p;
int N, nw;

int in;

float q(float x_, float y_){
  in = constrain(int(y_+height/2)*width + int(x_+width/2),0,img.pixels.length-1);
  return red(img.pixels[in])/255.0;
}

void thing(float r_) {
  N = int(2.5*r_);
  nw = int(.32*r_);
  beginShape();
  for (int i=0; i<N; i++) {
    th = i*TWO_PI/N;
    x = r_*cos(th);
    y = r_*sin(th);
    p = q(x,y);
    r = r_ + 7*p*cos(nw*th - TWO_PI*int(.025*r_+1)*t);
    vertex(r*cos(th), r*sin(th));
  }
  endShape(CLOSE);
}

PImage img;

void draw_() {
  push();
  translate(width/2,height/2);
  background(0);
  fill(255);
  noStroke();
  rotate(-TWO_PI/3*t);
  beginShape();
  for(int i=0; i<3; i++)
    vertex(315*cos(TWO_PI*i/3),315*sin(TWO_PI*i/3));
  endShape();
  pop();
  filter(BLUR,6);
  img = get();
  img.loadPixels();
  background(0); 
  stroke(40,180,240);
  push();
  translate(width/2, height/2);
  for (int i=0; i<20; i++)
    thing(30+25*i);
  pop();
}

gif: https://twitter.com/beesandbombs/status/898149534718676992