knot wave

knotwave.pde

int[][] result;
float t, c;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3), ia = atan(sqrt(.5));

void push() {
  pushMatrix();
  pushStyle();
}

void pop(){
  popStyle();
  popMatrix();
}

void draw() {
  
  if(!recording){
    t = mouseX*1.0/width;
    c = mouseY*1.0/height;
    if(mousePressed)
        println(c);
    draw_();
  }
  
  else {
  for (int i=0; i<width*height; i++)
    for (int a=0; a<3; a++)
      result[i][a] = 0;

  c = 0;
  for (int sa=0; sa<samplesPerFrame; sa++) {
    t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
    draw_();
    loadPixels();
    for (int i=0; i<pixels.length; i++) {
      result[i][0] += pixels[i] >> 16 & 0xff;
      result[i][1] += pixels[i] >> 8 & 0xff;
      result[i][2] += pixels[i] & 0xff;
    }
  }

  loadPixels();
  for (int i=0; i<pixels.length; i++)
    pixels[i] = 0xff << 24 | 
      int(result[i][0]*1.0/samplesPerFrame) << 16 | 
      int(result[i][1]*1.0/samplesPerFrame) << 8 | 
      int(result[i][2]*1.0/samplesPerFrame);
  updatePixels();

  saveFrame("frame-###.gif");
  if (frameCount==numFrames)
    exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 4;
int numFrames = 256;        
float shutterAngle = .6;

boolean recording = false;

int n = 600;
float r = 70;

float x(float q){
  return r*(sin(q) + 2*sin(2*q));
}

float y(float q){
  return r*(cos(q) - 2*cos(2*q));
}

float z(float q){
  return -r*sin(3*q);
}

float h = 1e-4;

float xp(float q){
  return (x(q+h/2)-x(q-h/2))/h;
}

float yp(float q){
  return (y(q+h/2)-y(q-h/2))/h;
}

float xpn(float q){
  return xp(q)/dist(xp(q),yp(q),0,0);
}

float ypn(float q){
  return yp(q)/dist(xp(q),yp(q),0,0);
}

float amt, th, dr = 1;
int nw = 11;

void knot(float ph){
  beginShape();
  for(int i=0; i<n; i++){
    th = TWO_PI*i/n;
    amt = 24*ease(map(cos(th-TWO_PI*t),1,-1,0,1),2.2);
    vertex(x(th)+amt*sin(nw*th+ph + dr*TWO_PI*t)*ypn(th),y(th)-amt*sin(nw*th+ph + dr*TWO_PI*t)*xpn(th),z(th));
  }
  endShape(CLOSE);
}

void setup() {
  size(640,640,P3D);
  ortho();
  result = new int[width*height][3];
  rectMode(CENTER);
  stroke(32);
  noFill();
  strokeWeight(7);
}

float x, y, z, tt;
int N = 12;

void draw_() {
  background(34,30,28); 
  push();
  translate(width/2, height/2 + 28);
  stroke(250);
  strokeWeight(5);
  knot(0);
  knot(PI);
  push();
  stroke(34,30,28);
  strokeWeight(16);
  translate(0,0,-12);
  knot(0);
  knot(PI);
  pop();
  pop();
}

gif: https://twitter.com/beesandbombs/status/874264180622331904