voip

voip.sh

#!/usr/bin/env zsh

# you can then forward the port pretty well using ssh -NR

# port to listen on
port=1337

###
#
# print error to stderr and return negative error code for chaining
#
function error()
{
	cat >& 2 <<<${@}
	return 1
}

###
#
# main function
#
function main()
{
	openssl rand -base64 24 \
		| read -r passphrase \
		|| error "cannot generate passphrase" \
		|| return 1

	cat <<<"password: ${passphrase}"

	zmodload -ab zsh/net/tcp ztcp \
		|| error "cannot load zsh/net/tcp" \
		|| return 1

	{
		ztcp -l ${port} \
			|| error "cannot listen" \
			|| return 1
		listenfd=${REPLY}

		while
			ztcp -a ${listenfd} \
				|| error "cannot accept connection"
		do
			currentfd=${REPLY}

			{
				ffmpeg -f alsa -i hw:0,0 -acodec libvorbis -f oga - 2>/dev/null \
					| PASSPHRASE=${passphrase} openssl enc -e -chacha20 -pass env:PASSPHRASE \
					| pv -Ppetra -CN input -B 8m \
					| cat >& ${currentfd} \
					&

				cat <& ${currentfd} \
					| pv -Ppetra -CN output -B 8m \
					| PASSPHRASE=${passphrase} openssl enc -d -chacha20 -pass env:PASSPHRASE \
					| ffplay -nodisp 2>/dev/null \
					&

				wait
			} \
			always \
			{
				ztcp -c ${currentfd} \
					|| error "cannot close currentfd" \
					|| return 1
			}
		done

	} \
	always \
	{
		ztcp -c ${listenfd} \
			|| error "cannot close listenfd" \
			|| return 1
	}
}

main ${@}