Pop up a notification prompting you to close Slack if it's open

slack_watcher.scpt

tell application "System Events"
	set activeApp to name of first process whose frontmost is true
end tell

if application "Slack" is running and activeApp is not equal to "Slack" then
	tell application "Notifications Scripting"
		# set show event handler results to true
		set event handlers script path to (path to me)
		
		display notification "Slack is running" message "Are you waiting on an @mention?" action button "No" other button "Yes"
	end tell
end if

using terms from application "Notifications Scripting"
	on notification activated activation type 2 # action button
		tell application "Slack" to quit
	end notification activated
end using terms from

I couldn't figure out how to display a system notification with custom buttons that tell you which button was clicked. Instead I used Finder to display the notification—a little bit hacky, but it works.

I put this in ~/bin/slack_watcher.applescript:

tell application "System Events"
        set activeApp to name of first process whose frontmost is true
end tell

if application "Slack" is running and activeApp is not equal to "Slack" then
        tell application "Finder"
                activate
                display alert "Slack is running" message "Are you waiting on an @mention?" buttons ["No", "Yes"] default button 1
        end tell

        using terms from application "AppleScript Utility"
                if button returned of result = "No" then
                        tell application "Slack" to quit
                end if
        end using terms from
end if

Then I added this to the crontab (crontab -e) to have the script run every 5 minutes:

*/5 * * * * osascript $HOME/bin/slack_watcher.applescript

@patbl Awesome! Thanks!